PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Daniel Peukert <daniel@peukert.cc>
_projectname='mew'
pkgname="ocaml-$_projectname"
pkgver='0.1.0'
_commit='e2a5ca84d9c3c4142a47ef867b2bbc44083246c5'
pkgrel='8'
pkgdesc='A general modal editing engine generator'
arch=('x86_64' 'aarch64')
url="https://github.com/kandu/$_projectname"
license=('MIT')
depends=('ocaml>=4.02.3' 'ocaml-result' 'ocaml-trie')
makedepends=('dune>=1.1.0')
checkdepends=('ocaml-ppx_expect')
options=('!strip')
source=("$pkgname-$pkgver::git+$url#commit=$_commit?signed")
sha512sums=('ddd64148ac9e746b03d96fa08505fe2b56d290703bbeb5658043c8a057222ff11bc61c188de6c6c42692e780e9a2b39019ff87e3ab2379bfc369f79f7827cf1e')
validpgpkeys=('364216C4466A9E17A97CD5DBEECA66966D9E4261') # ZAN DoYe <zandoye@gmail.com> (https://github.com/kandu.gpg)

_sourcedirectory="$pkgname-$pkgver"

build() {
	cd "$srcdir/$_sourcedirectory/"
	dune build --release --verbose
}

check() {
	cd "$srcdir/$_sourcedirectory/"
	dune runtest --release --verbose
}

package() {
	cd "$srcdir/$_sourcedirectory/"
	DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir '/usr/lib/ocaml' --docdir '/usr/share/doc' --mandir '/usr/share/man' --release --verbose

	for _folder in "$pkgdir/usr/share/doc/"*; do
		mv "$_folder" "$pkgdir/usr/share/doc/ocaml-$(basename "$_folder")"
	done

	install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
	ln -sf "/usr/share/doc/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/MIT"
}