blob: 50338bec4d9f5a0cf1881483a68c24aa3a1ed194 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Marcin (CTRL) Wieczorek <marcin@marcin.co>
# Contributor: Simon (vodik) Gomizelj <simongmzlj@gmail.com>
# Contributor: Eduardo Leggiero <https://www.leggiero.uk/>
# Contributor: jyantis <yantis@yantis.net>
# Contributor: jcsiv <siviter dot jamie at gmx dot co dot uk>
# Contributor: ThinCarrotShrimp <christoph.r.martin+arch at gmail dot com>
pkgname=oh-my-zsh-git
pkgver=r6192.be4a95297
pkgrel=1
pkgdesc="A community-driven framework for managing your zsh configuration. Includes 180+ optional plugins and over 120 themes to spice up your morning, and an auto-update tool so that makes it easy to keep up with the latest updates from the community"
arch=('any')
url='https://github.com/ohmyzsh/ohmyzsh'
license=('MIT')
depends=('zsh')
makedepends=('git')
optdepends=('ruby: for some plugin functionality'
'python: for some plugin functionality'
'oh-my-zsh-powerline-theme-git: great theme'
'bullet-train-oh-my-zsh-theme-git: better powerline theme'
'git: most themes use git (highly recommended but still optional)')
install=${pkgname}.install
source=("${pkgname}::git+https://github.com/ohmyzsh/ohmyzsh.git"
'0001-zshrc.patch')
sha256sums=('SKIP'
'c8a559712110031585410328fdd3fffa2d16511b72caf5d46698b0f7d56cbcb7')
# conflicts=('grml-zsh-config'
# 'grml-zsh-config-git')
pkgver() {
cd ${pkgname}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${pkgname}"
cp "templates/zshrc.zsh-template" "zshrc"
patch -p1 < "${srcdir}/0001-zshrc.patch"
}
package() {
cd "${srcdir}/${pkgname}"
mkdir -p "${pkgdir}/usr/share/oh-my-zsh"
install -D -m644 "LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cp -r * "${pkgdir}/usr/share/oh-my-zsh/"
}
# vim:set ts=2 sw=2 et:
|