PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

# Maintainer: Adrian Perez de Castro
pkgdesc='SVG optimizer'
pkgname=ohmysvg
pkgver=1.5
pkgrel=1
url=https://github.com/sonnyp/OhMySVG/
arch=(any)
license=(GPL-3.0-or-later)
depends=(gjs hicolor-icon-theme libadwaita)
makedepends=(blueprint-compiler git meson)
_troll_commit=8b0275948eedec9ed0378f9bdda1aa4aac3062ba
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "git+https://github.com/sonnyp/troll#commit=$_troll_commit")
b2sums=('e2bb03c8e86149efd17db43500d36503e7ad0d61979707f6ae9e94704e23289c7c22e6b1e9cffcf150101b5c39a896f3c1d0bcdc07efa5c5f84184cc4aead191'
        '19bd1ff8c832c4bda4a055e28fdbf3ca64d431179f8c06f1611634918c9a9000de0aa40fd9f79b6d142b07ee13c31818b84a01f412a48a4f11b028b0f73d01b0')

prepare () {
	rm -vrf "OhMySVG-${pkgver%.0}/troll"
	ln -vsfn "$srcdir/troll" "OhMySVG-${pkgver%.0}/troll"
}

build () {
	arch-meson _build "OhMySVG-${pkgver%.0}"
	meson compile -C _build
}

package () {
	meson install -C _build --destdir="${pkgdir}"
}