blob: 8b43f0e2cefcaae71d0f15316bf866d25b5b131d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Maintainer: Zack Baldwin <zack@zackb.com>
pkgname=ombi
pkgver=4.43.5
pkgrel=1
pkgdesc='Simple automated way for users to request new content for Plex'
arch=('x86_64' 'aarch64' 'armv7h')
url='https://github.com/Ombi-app/Ombi'
license=('GPL2')
depends=('libunwind' 'openssl-1.0' 'icu')
optdepends=('sonarr: TV daemon for usenet & torrents'
'radarr: Movie daemon for usenet & torrents (sonarr fork)'
'lidarr: Music daemon for usenet & torrents (sonarr fork)'
'sickrage: TV daemon for usenet & torrents (sickbeard fork)'
'couchpotato: Movie daemon for usenet & torrents'
'plex-media-server: Media server'
'plex-media-server-plexpass: Media server (plexpass version)'
'emby-server: Media server')
backup=('var/lib/ombi/appsettings.json')
replaces=('plexrequests')
options=('!strip' 'staticlibs')
source=("ombi.service"
"ombi.sysusers"
"ombi.tmpfiles")
# https://github.com/Ombi-app/Ombi/releases/download/v4.0.1342/linux-x64.tar.gz
source_x86_64=("ombi-x86_64-${pkgver}.tar.gz::https://github.com/Ombi-app/Ombi/releases/download/v${pkgver}/linux-x64.tar.gz")
source_armv7h=("ombi-armv7h-${pkgver}.tar.gz::https://github.com/Ombi-app/Ombi/releases/download/v${pkgver}/linux-arm.tar.gz")
source_aarch64=("ombi-aarch64-${pkgver}.tar.gz::https://github.com/Ombi-app/Ombi/releases/download/v${pkgver}/linux-arm64.tar.gz")
noextract=("ombi-x86_64-${pkgver}.tar.gz"
"ombi-i686-${pkgver}.tar.gz"
"ombi-armv7h-${pkgver}.tar.gz")
sha256sums=('263c0f3bce912441c8473203096958c8037e577df879403f6f93ac9317cee185'
'6efc381990e1113737686d4f61795095fa8edbc176daa877fd755f1ddb3a40fa'
'49fc5edca9d88fc9d6e9f0f4a6d707b072f32daa097305f0bf905dfff342f44a')
sha256sums_x86_64=('e37e374bd7f1366a1985b7eafd901f236c05ed9c08c3b232cb2654b206b8f19a')
sha256sums_aarch64=('5e747fb93ef796e292a58afa89e672bb49a33b2db75c6b395150e47b4214f4f4')
sha256sums_armv7h=('7c8fc3a079395c645c4e514e6f4987844fc45eea3ea7679948adee1ccf7f4435')
prepare() {
# The source is packaged w/o a sub directory, so create our own and
# extract to it. Arm package has a different name too.
mkdir -p "${srcdir}/ombi"
bsdtar -x -C "${srcdir}/ombi" -f "ombi-${CARCH}-${pkgver}.tar.gz"
}
package() {
# Copy the default appsettings.json
install -d -m 755 "${pkgdir}/var/lib/ombi"
install -D -m 644 "${srcdir}/ombi/appsettings.json" "${pkgdir}/var/lib/ombi/"
#install -D -m 644 "${srcdir}/ombi/HealthCheck.css" "${pkgdir}/var/lib/ombi/"
# Copy in files and then fix permissions
install -d -m 755 "${pkgdir}/usr/lib/ombi"
cp -dpr --no-preserve=ownership "${srcdir}/ombi/"* "${pkgdir}/usr/lib/ombi/"
chmod -R a=,a+rX,u+w ${pkgdir}/usr/lib/ombi/
chmod 755 ${pkgdir}/usr/lib/ombi/Ombi
install -D -m 644 "${srcdir}/ombi.service" "${pkgdir}/usr/lib/systemd/system/ombi.service"
install -D -m 644 "${srcdir}/ombi.sysusers" "${pkgdir}/usr/lib/sysusers.d/ombi.conf"
install -D -m 644 "${srcdir}/ombi.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/ombi.conf"
}
# vim:set ts=2 sw=2 et:
|