blob: 6dca140e3991aac4bc92390831f09c76fe3d7af2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="omekasy"
pkgver=1.3.3
pkgrel=1
pkgdesc="Convert alphanumeric characters to various styles defined in Unicode"
arch=('aarch64' 'x86_64')
url="https://github.com/ikanago/${pkgname}"
license=('MIT')
depends=('gcc-libs' 'glibc')
makedepends=('cargo')
_pkgsrc="${url##*/}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('0def519ad64396aa12b341dee459049fb54a3cfae265ae739da5e65ca1d7e377')
prepare() {
cd "${srcdir}/${_pkgsrc}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "${srcdir}/${_pkgsrc}"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -Dm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|