blob: 17aa79ce8fe3fcf3d42bac8b391abe1601388409 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
pkgname=openafs-modules
_srcname=openafs
pkgver=1.6.22
pkgrel=1
pkgdesc="Kernel module for OpenAFS"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.openafs.org"
license=('custom:"IBM Public License Version 1.0"')
depends=('openafs')
makedepends=('linux-headers')
conflicts=('openafs-features-libafs' 'openafs<1.6.6-2')
options=(!emptydirs)
source=(http://openafs.org/dl/${pkgver}/${_srcname}-${pkgver}-src.tar.bz2
0001-Correct-m4-conditionals-in-curses.m4.patch
0002-Linux-Test-for-__vfs_write-rather-than-__vfs_read.patch
0003-Linux-Use-kernel_read-kernel_write-when-__vfs-varian.patch)
install=openafs-modules.install
sha256sums=('835410b75d14aec1ac6a1138d8194897f1badeffa3a0c282963ad51996712347'
'7d4b9bd370ae00aad978db7ad82950598817c205727e6fa2062c0e0c2ace289a'
'9472094ff5f35ca2cc50dcad26f40274a6b409ecc49b80668cf06081e6bf71d9'
'b713e7cf5c295254d8e9abe277fd686a89e5e48f27f128761585320a3088ff27')
# Heuristic to determine version of installed kernel
# You can modify this if the heuristic fails
_extramodules=$(ls -dt /usr/lib/modules/extramodules-* | head -n1)
_kernelver=$(cat ${_extramodules}/version)
prepare() {
cd ${srcdir}/${_srcname}-${pkgver}
# Fix curses checks during configure (https://gerrit.openafs.org/12740/)
patch -p1 < ${srcdir}/0001-Correct-m4-conditionals-in-curses.m4.patch
# Fix compatibility with Linux 4.14
patch -p1 < ${srcdir}/0002-Linux-Test-for-__vfs_write-rather-than-__vfs_read.patch
patch -p1 < ${srcdir}/0003-Linux-Use-kernel_read-kernel_write-when-__vfs-varian.patch
# Only needed when changes to configure were made
./regen.sh -q
}
build() {
cd ${srcdir}/${_srcname}-${pkgver}
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib \
--disable-fuse-client \
--with-linux-kernel-packaging \
--with-linux-kernel-build="/usr/lib/modules/${_kernelver}/build"
make only_libafs
}
package() {
cd ${srcdir}/${_srcname}-${pkgver}
make DESTDIR=${pkgdir} install_only_libafs
# install kernel module
install -dm755 ${pkgdir}${_extramodules}
mv ${pkgdir}/lib/modules/${_kernelver}/extra/openafs/openafs.ko ${pkgdir}${_extramodules}/openafs.ko
gzip -9 ${pkgdir}${_extramodules}/openafs.ko
# install license
install -Dm644 ${srcdir}/${_srcname}-${pkgver}/src/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
# remove file already included in openafs package)
rm -rf ${pkgdir}/usr/bin ${pkgdir}/usr/include
find ${pkgdir} -name *.a -delete
# update major kernel version in install file
sed -i "s/depmod .*/depmod ${_kernelver}/g" "${startdir}/openafs-modules.install"
}
|