blob: c3d63bf57bb558283debab5f837a6da7580aee8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
pkgname=openmpi3-gcc8
_pkgname=openmpi
pkgver=3.1.6
_gccver=8.4.0
pkgrel=1
pkgdesc='High performance message passing library (MPI), version 3 (built with GCC8)'
url='https://www.open-mpi.org'
arch=('x86_64')
license=('custom:OpenMPI')
depends=('libltdl' 'hwloc<2' 'openssh' 'zlib' 'libnl' 'gcc8' 'gcc8-libs')
makedepends=('inetutils' 'valgrind' 'gcc8-fortran')
optdepends=('gcc8-fortran: fortran support')
conflicts=('openmpi')
provides=("openmpi=${pkgver}")
options=('staticlibs')
source=(https://www.open-mpi.org/software/ompi/v${pkgver%.*}/downloads/${_pkgname}-${pkgver}.tar.bz2)
sha256sums=('50131d982ec2a516564d74d5616383178361c2f08fdd7d1202b80bdf66a0d279')
sha512sums=('23d39e6f6f68107aa03d9f37e673c739cedb3b63731b693be3d0def236863ce6e8405f93de1734e0725c33674b6873bbf5179108fa13138dea49cee792c868bc')
build() {
cd ${_pkgname}-${pkgver}
export LD_LIBRARY_PATH="/usr/lib/gcc/x86_64-pc-linux-gnu/${_gccver}:$LD_LIBRARY_PATH"
export LD_PRELOAD=/usr/lib/libstdc++.so
./configure --prefix=/usr \
--sysconfdir=/etc/${_pkgname} \
--enable-mpi-fortran=all \
--libdir=/usr/lib/${_pkgname} \
--with-threads=posix \
--enable-mpi-thread-multiple \
--enable-smp-locks \
--enable-builtin-atomics \
--enable-mpi-cxx \
--with-valgrind \
--enable-memchecker \
--enable-pretty-print-stacktrace \
--without-slurm \
--with-hwloc=/usr \
--with-libltdl=/usr \
CC=/usr/bin/gcc-8 CXX=/usr/bin/g++-8 FC=/usr/bin/gfortran-8 \
LDFLAGS="${LDFLAGS} -Wl,-z,noexecstack"
make
}
check() {
cd ${_pkgname}-${pkgver}
make check
}
package() {
cd ${_pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# FS#28583
install -dm 755 "${pkgdir}/usr/lib/pkgconfig"
for i in ompi-c.pc ompi-cxx.pc ompi-f77.pc ompi-f90.pc ompi.pc; do
ln -sf "/usr/lib/${_pkgname}/pkgconfig/${i}" "${pkgdir}/usr/lib/pkgconfig/"
done
install -dm 755 "${pkgdir}/etc/ld.so.conf.d"
echo "/usr/lib/${_pkgname}" > "${pkgdir}"/etc/ld.so.conf.d/${_pkgname}.conf
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${_pkgname}"
}
|