blob: 6fbfa6a2490ae117b5396bead1a9f3cfda3cd330 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Kyle Brooks <brookskd@gmail.com>
pkgname=openmvg-git
pkgver=1.0.r0.g944254c
pkgrel=4
pkgdesc='open Multiple View Geometry library. Basis for 3D computer vision and Structure from Motion.'
arch=('i686' 'x86_64')
url='http://imagine.enpc.fr/~moulonp/openMVG/'
license=('MPL')
depends=('libpng' 'libjpeg' 'libtiff' 'libxrandr' 'libxxf86vm' 'libxi' 'graphviz' 'libgl' 'ceres-solver' 'flann' 'coin-or-coinutils' 'coin-or-clp' 'coin-or-osi' 'coin-or-lemon')
makedepends=('git' 'cmake' 'doxygen' 'eigen')
_gitname='openMVG'
source=("git+https://github.com/openMVG/${_gitname}.git"
'git+https://github.com/elmindreda/glfw.git'
'git+https://github.com/openMVG-thirdparty/osi_clp.git'
'git+https://github.com/openMVG-thirdparty/cereal.git'
'libopenMVG_sfm_link_error.patch'
)
md5sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'8e1dd6742b2ed87b1086829e75d69cee'
)
pkgver() {
cd "${srcdir}/${_gitname}"
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_gitname}"
git submodule init
git config 'submodule.src/dependencies/glfw.url' "${srcdir}/glfw"
git config 'submodule.src/dependencies/osi_clp.url' "${srcdir}/osi_clp"
git config 'submodule.src/dependencies/cereal.url' "${srcdir}/cereal"
git submodule update
git apply ../libopenMVG_sfm_link_error.patch
}
build() {
cd "${srcdir}"
mkdir -p openmvg_build
cd openmvg_build
cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RELEASE -DOpenMVG_BUILD_SHARED=ON -DOpenMVG_BUILD_EXAMPLES=ON -DOpenMVG_BUILD_DOC=ON -DOpenMVG_BUILD_OPENGL_EXAMPLES=ON -DOpenMVG_USE_OPENMP=ON -DFLANN_INCLUDE_DIR_HINTS=/usr/include -DCOINUTILS_INCLUDE_DIR_HINTS=/usr/include/coin -DCLP_INCLUDE_DIR_HINTS=/usr/include/coin -DOSI_INCLUDE_DIR_HINTS=/usr/include/coin -DLEMON_INCLUDE_DIR_HINTS=/usr/include -DCERES_DIR_HINTS=/usr/share/Ceres -DEIGEN_INCLUDE_DIR_HINTS=/usr/include/eigen3 ../openMVG/src/
make
}
package() {
cd "${srcdir}/openmvg_build"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|