blob: 6c9766b492c372c9db29bbbbf514d058131a25f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Merlin Glander <merlin@merlin-glander.de>
_orgname=OpenOrienteering
_pkgname=mapper
pkgname=${_orgname,,}-${_pkgname}
pkgver=0.9.6
pkgrel=1
pkgdesc='Map drawing program from OpenOrienteering'
arch=(x86_64)
url='https://www.openorienteering.org/apps/mapper/'
license=('GPL-3.0-only')
depends=(
'qt5-base'
'qt5-serialport'
'qt5-location'
'qt5-sensors'
'polyclipping'
'proj'
'gdal'
'hicolor-icon-theme'
)
makedepends=(
'cmake'
'qt5-tools'
'doxygen'
'libcups'
)
checkdepends=('qt5-imageformats')
optdepends=(
'qt5-imageformats: Support for TIFF etc.'
'qt5-translations: for Qt5 dialog translations'
)
provides=("${pkgname}=${pkgver}")
conflicts=("${pkgname}-git")
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/${_orgname}/${_pkgname}/archive/v${pkgver}.tar.gz"
)
sha256sums=('8fd306029b89c3dddfe816723e346bb61069354e506657ce66f5fcfc87a6daff')
build() {
cd "${_pkgname}-${pkgver}"
sed -e 's/LICENSE/LICENSE.TXT/' -i doc/licensing/arch-licensing.cmake
rm -rf build
cmake -S . -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLICENSING_PROVIDER=arch \
-DMapper_PACKAGE_NAME="${pkgname}" \
-Wno-dev
cmake --build build
}
check() {
cd "${_pkgname}-${pkgver}"
cmake --build build --target test
}
package() {
cd "${_pkgname}-${pkgver}"
DESTDIR="${pkgdir}" cmake --build build --target install
}
|