blob: b979c6c8ab9fde108ab768170fad900e3389aef6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Cory Sanin <corysanin@outlook.com>
_basename="openrct2"
_pkgname="${_basename}-appimage"
_version="v0.4.19.1-7-g0886df6244"
pkgname=${_basename}-appimage
pkgdesc="Develop appimages for OpenRCT2"
pkgver=0.4.19.1.7
pkgrel=1
provides=("${pkgname}")
conflicts=("${pkgname}")
url="https://openrct2.io"
arch=("x86_64")
license=("GPL3")
_appimage="${_basename}-${pkgver}.AppImage"
source=("${_appimage}"::"https://github.com/OpenRCT2/OpenRCT2-binaries/releases/download/${_version}/OpenRCT2-${_version}-linux-x86_64.AppImage")
sha256sums=('3ec1d80bbd1f477e50d35b1e67cada618b9ab09ad96053636e771e6f46200608')
options=(!strip)
prepare() {
chmod +x "${srcdir}/${_appimage}"
"./${_appimage}" --appimage-extract
# Append appimage to appimage in desktop file
sed -i -E "s:openrct2:openrct2-appimage:" "${srcdir}/squashfs-root/${_basename}.desktop"
sed -i -E "s:OpenRCT2:OpenRCT2 AppImage:" "${srcdir}/squashfs-root/${_basename}.desktop"
# Update icon filenames
for f in ${srcdir}/squashfs-root/usr/share/icons/hicolor/*/apps/*.*; do mv "${f}" "$(echo "${f}" | sed s:/openrct2\\.:/openrct2-appimage.:)"; done
}
package() {
# Appimage and symlink
install -Dpm755 "${_appimage}" "${pkgdir}/opt/${pkgname}/${_appimage}"
install -dm755 "${pkgdir}/usr/bin"
ln -s "/opt/${pkgname}/${_appimage}" "${pkgdir}/usr/bin/${pkgname}"
# Desktop file
install -Dm644 "${srcdir}/squashfs-root/${_basename}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Icons
install -dm755 "${pkgdir}/usr/share/"
cp -r --no-preserve=mode,ownership "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
}
|