blob: 7672e2fa27c02b756c78b9d3124ea29b668de6ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Sergio Tridente <tioduke (at) gmail (dot) com>
pkgname=oracle-datamodeler
_pkgver=24.3.0.240
_pkgrel=1210
pkgver=${_pkgver}.${_pkgrel}
pkgrel=1
pkgdesc="A data modeling and database design tool that provides an environment for capturing, modeling, managing, and exploiting metadata"
arch=('any')
url="http://www.oracle.com/technetwork/developer-tools/datamodeler/overview/index.html"
license=('custom:OTN')
depends=('java-environment=17' 'bash')
optdepends=(
"java17-openjfx: Required to run the application with JDK17"
)
install=$pkgname.install
source=(manual://datamodeler-${_pkgver}.${_pkgrel}-no-jre.zip
$pkgname.desktop
$pkgname.sh
LICENSE-OTN
java_home.patch)
DLAGENTS+=('manual::/usr/bin/echo The source file for this package need to be downloaded manually, since it requires a login and is not redistributable. Please visit https://www.oracle.com/tools/downloads/sql-data-modeler-downloads.html')
sha256sums=('5dc7221a28707c9403ce8193bd7d50c32cb5c07bfc0d765bc6e6f3b22149fe52'
'9618cf10af64c767c7ca3f90f54522e93f10c9766312b4a06fc9384a9e3c6cc8'
'd61ad1cd5f6f6e665471c2b6537654beda625f24a50e19156c4fbbccebc16a24'
'5919502a2b23a78fff277b642c8b2b989d415dd6de6fb6089424d888809a9257'
'78c837551bf1e3e6e085ddb5f0034e04b527d37fbf43a74d867af4b70cdc7972')
prepare() {
cd "$srcdir"/datamodeler
patch -Np1 < "$srcdir/java_home.patch"
find . \( -iname "*.exe" -o -iname "*.dll" \) -exec rm -f "{}" +
}
package() {
cd "$srcdir"/datamodeler
find . -type f -exec install -Dm644 "{}" "$pkgdir/opt/$pkgname/{}" \;
chmod +x "$pkgdir/opt/$pkgname/datamodeler.sh"
chmod +x "$pkgdir/opt/$pkgname/datamodeler/bin/datamodeler"
chmod +x "$pkgdir/opt/$pkgname/ide/bin/launcher.sh"
chmod a+w -R "$pkgdir/opt/$pkgname/datamodeler/types"
install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 "$srcdir/LICENSE-OTN" "$pkgdir/usr/share/licenses/$pkgname/LICENSE-OTN"
}
|