PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=oryx-kb-leds
pkgver=1.1
pkgrel=6
pkgdesc="Control your Oryx Pro's Keyboard LEDs"
arch=('x86_64')
url="https://github.com/davemcphee/oryx-kb-leds"
license=('GPL-3.0-or-later')
depends=(
  'python-colour'
  'python-psutil'
  'python-pyaml'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
optdepends=(
  'system76-dkms: Control hotkeys and fan on certain System76 laptops'
)
install="$pkgname.install"
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('d1ebeaf7464147beb3dba36e629b0e0afe5e31c6243cef298998eb2afe240a16')

prepare() {
  cd "$pkgname-$pkgver"

  # pytest-runner not required
  sed -i '/setup_requires/d' setup.py
}

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -Dm644 systemd/oryxkbleds.service -t "$pkgdir/usr/lib/systemd/system/"
  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}