PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: bemxio <bemxiov at protonmail dot com>

pkgname="osaka-simulator"
pkgdesc="A fanmade interactive Osaka simulator from hirahira.net for PC"

pkgver=Aug_2003
pkgrel=3

arch=(any)

url="https://azumanga.fandom.com/wiki/Ayumu_Kasuga%27s_Mail_Order_Life"
license=("LicenseRef-unknown")

depends=(wine winetricks)
makedepends=(unzip gendesk icoutils)

provides=(osaka-simulator)

source=("file://Osaka Simulator FINAL (standalone).zip" "osaka-simulator" "tsu_han.cfg")
md5sums=("69c5e729bd4acc28320afbcc863b454a" "8af04a78b75b73656908f722d6cbce19" "7b644ee8fdf4d1b8213115bef3a1b90c")

DLAGENTS=("file::/usr/bin/echo Could not find %u. Please download it to `$(pwd)` in order to build the package.")

prepare() {
	# extract the icon out of the executable
	wrestool -x -n 128 "Osaka Simulator FINAL/tsu_han.exe" -o OsakaSimulator.ico

	# get the highest quality PNG from the icon file
	icotool -x OsakaSimulator.ico -i 3 -o OsakaSimulator.png

	# generate a .desktop file
	gendesk -f -n \
		--pkgname "Ayumu Kasuga's Mail Order Life" \
		--pkgdesc "${pkgdesc}" \
		--exec osaka-simulator \
		--icon osaka-simulator.png \
		--categories "Game;Simulation"
}

package() {
	# make the required directory
	mkdir -p "${pkgdir}/opt/osaka-simulator"

	# copy the game's files
	cp -r "Osaka Simulator FINAL"/* "${pkgdir}/opt/osaka-simulator"

	# delete the bundled-in save file and configuration file
	rm -f "${pkgdir}/opt/osaka-simulator/tsu_han.dat"
	rm -f "${pkgdir}/opt/osaka-simulator/tsu_han.cfg"

	# copy the package's configuration file
	install -Dm644 tsu_han.cfg "${pkgdir}/opt/osaka-simulator/tsu_han.cfg"

	# set the ownership of the game's directory to root:games
	chown -R root:games "${pkgdir}/opt/osaka-simulator"

	# copy the executable script
	install -Dm755 osaka-simulator "${pkgdir}/usr/bin/osaka-simulator"

	# copy the extracted icon and the generated .desktop file
	install -Dm644 OsakaSimulator.png "${pkgdir}/usr/share/pixmaps/osaka-simulator.png"
	install -Dm644 "Ayumu Kasuga's Mail Order Life.desktop" "${pkgdir}/usr/share/applications/osaka-simulator.desktop"
}