blob: 21c146b3642973739beb6fcc5775349e2db29bd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Vadim Yanitskiy <fixeria@osmocom.org>
# Contributor: Josef Miegl <josef@miegl.cz>
pkgname=osmo-trx
pkgver=1.6.2
pkgrel=1
pkgdesc="GSM Radio Modem based on a fork of the OpenBTS Transceiver program"
url="https://osmocom.org/projects/osmotrx"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
license=('AGPL-3.0-only')
depends=('libosmocore'
'libusb'
'libuhd' # --with-uhd
'limesuite' # --with-lms
'talloc'
'fftw')
makedepends=('boost')
conflicts=("${pkgname}-git")
backup=('etc/osmocom/osmo-trx-uhd.cfg'
'etc/osmocom/osmo-trx-lms.cfg'
'etc/osmocom/osmo-trx-ipc.cfg')
source=("https://downloads.osmocom.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.bz2")
sha256sums=('2103d68d98c18899adc54df12b442fb85ffb1d7f628bff2f46114eb9b44cb417')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-uhd \
--with-lms \
--with-ipc
# --enable-mstrx
# --with-bladerf
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR=${pkgdir} install
}
# vim:set ts=2 sw=2 et:
|