blob: b45576eaa9764245ab55eb57c6e795736e1f52c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Jan Bidler <janbidler00 at protonmail dot com>
# PKGBUILD from the official pacman package:
# https://github.com/archlinux/svntogit-packages/edit/packages/pacman/trunk/PKGBUILD
# The pacman maintainers are thus honored here:
# Contributor Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor Morten Linderud <foxboron@archlinux.org>
pkgname=pacman-pb
pkgver=6.0.2
pkgrel=4
pkgdesc="A library-based package manager with dependency support - includes a patch to customize the progress bar"
arch=('x86_64')
url="https://www.archlinux.org/pacman/"
license=('GPL')
groups=('base-devel')
depends=('bash' 'glibc' 'libarchive' 'curl' 'gpgme' 'pacman-mirrorlist'
'gettext' 'gawk' 'coreutils' 'gnupg' 'grep')
makedepends=('meson' 'asciidoc' 'doxygen')
checkdepends=('python' 'fakechroot')
optdepends=('perl-locale-gettext: translation support in makepkg-template')
provides=('libalpm.so' 'pacman=${pkgver%.*.*}')
conflicts=('pacman')
backup=(etc/pacman.conf
etc/makepkg.conf)
options=('strip' 'debug')
#validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD' # Allan McRae <allan@archlinux.org>
# 'B8151B117037781095514CA7BBDFFC92306B1121') # Andrew Gregory (pacman) <andrew@archlinux.org>
source=(https://sources.archlinux.org/other/pacman/pacman-$pkgver.tar.xz
pacman-always-create-directories-from-debugedit.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/efd0c24c07b86be014a4edb5a8ece021b87e3900.patch
pacman-always-create-directories-from-debugedit-fixup.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/86981383a2f4380bda26311831be94cdc743649b.patch
pacman-fix-unique-source-paths.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/478af273dfe24ded197ec54ae977ddc3719d74a0.patch
pacman-strip-include-o-files-similar-to-kernel-modules.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/de11824527ec4e2561e161ac40a5714ec943543c.patch
pacman.conf
makepkg.conf
0001-Make-progress-bar-characters-customizable.patch)
sha256sums=('7d8e3e8c5121aec0965df71f59bedf46052c6cf14f96365c4411ec3de0a4c1a5'
'522b789e442b3bb3afa7ea3fa417a99554f36ec00de3986cbe92c80f09a7db99'
'dab7c70fb9d77d702069bb57f5a12496b463d68ae20460fb0a3ffcb4791321a9'
'0b56c61eac3d9425d68faa2eccbaefdc5ed422b643974ae829eaca0460043da1'
'acd0b149b6324dc1eca3cd2d3b30df6ef64c5653e83523d77200ec593e01d2a7'
'38319372438e9c4bb840cc5d0a584fc105421705a4f956d9aab832c2be18c6e8'
'072020e34f2c55b94a9a486829a7eadab0a830ddb4d8e759b0c4e6cf1bde73a6'
'0ec6abce23dd1812a577b729bf5a0d593bc8af60d263d068321538beee656ca8')
prepare() {
cd "pacman-${pkgver}"
# we backport way too often in pacman
# lets at least make it more convenient
local src
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
msg2 "Applying patch $src..."
patch -Np1 < "../$src"
done
}
build() {
cd "pacman-$pkgver"
meson --prefix=/usr \
--buildtype=plain \
-Ddoc=enabled \
-Ddoxygen=enabled \
-Dscriptlet-shell=/usr/bin/bash \
-Dldconfig=/usr/bin/ldconfig \
build
meson compile -C build
}
check() {
cd "pacman-$pkgver"
meson test -C build
}
package() {
cd "pacman-$pkgver"
DESTDIR="$pkgdir" meson install -C build
# install Arch specific stuff
install -dm755 "$pkgdir/etc"
install -m644 "$srcdir/pacman.conf" "$pkgdir/etc"
install -m644 "$srcdir/makepkg.conf" "$pkgdir/etc"
}
|