blob: 19a53912f63bea6a2d0f81e79afc84d628dee8bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Cody <aur AT codyps.com>
pkgname=pahole-git
pkgdesc="Various DWARF utils"
pkgver=1.13.r6.g568dae4
pkgrel=1
arch=('i686' 'x86_64')
url="http://git.kernel.org/?p=devel/pahole/pahole.git;a=summary"
license=('GPL2')
depends=('elfutils' 'python')
makedepends=('git' 'cmake' 'ninja')
provides=('dwarves' 'pahole')
conflicts=('dwarves' 'pahole')
source=(
$pkgname::'git+https://kernel.googlesource.com/pub/scm/devel/pahole/pahole.git'
'git+https://github.com/libbpf/libbpf'
)
md5sums=('SKIP' 'SKIP')
prepare() {
cd "$srcdir"
mkdir -p build
cd "$srcdir/$pkgname"
git submodule init
git config submodule.libbpf.url "$srcdir/libbpf"
git submodule update
}
pkgver() {
cd "$srcdir/$pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
cd "$srcdir/build"
cmake -G Ninja \
-D CMAKE_BUILD_TYPE=Plain \
-D CMAKE_INSTALL_PREFIX=/usr \
-D LIB_INSTALL_DIR=/usr/lib \
../"$pkgname"
ninja -v
}
package() {
cd "$srcdir/build"
DESTDIR=${pkgdir}/ ninja install
}
# vim:set ts=2 sw=2 et:
|