blob: a3665ac1e6ba5acee2705d54a6863d683acf8d2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor: artiom <a.mv at gmx dot fr>
# Contributor: ilikenwf
# Contributor: American_Jesus
pkgname=palemoon
_repo=Pale-Moon
pkgver=28.9.0.1
_commit=b5586a366a3cb44c82ba60f6122786b3d757431e
pkgrel=1
pkgdesc="Open source web browser based on Firefox focusing on efficiency."
arch=('i686' 'x86_64')
url="https://www.palemoon.org/"
license=('MPL' 'GPL' 'LGPL')
depends=('gtk2' 'dbus-glib' 'desktop-file-utils' 'libxt' 'mime-types' 'alsa-lib'
'startup-notification')
makedepends=('git' 'python2' 'autoconf2.13' 'unzip' 'zip' 'yasm' 'gconf'
'libpulse')
optdepends=('libpulse: PulseAudio audio driver'
'ffmpeg: various video and audio support')
source=(git+"https://github.com/MoonchildProductions/${_repo}?signed#commit=${_commit}"
git+"https://github.com/MoonchildProductions/UXP"
mozconfig.in)
sha1sums=('SKIP'
'SKIP'
'802731e5af4d117961d3d6fc61bd1e23f69fd384')
validpgpkeys=('3059E09144F56804F0FBF4E126B40624BDBFD9F3')
prepare() {
sed 's#%SRCDIR%#'"${srcdir}"'#g' mozconfig.in > mozconfig
cd ${_repo}
git submodule init
git config submodule.platform.url "${srcdir}/UXP"
git submodule update
}
build() {
cd ${_repo}
export MOZBUILD_STATE_PATH="${srcdir}/mozbuild"
export MOZCONFIG="${srcdir}/mozconfig"
export CPPFLAGS="${CPPFLAGS} -O2 -Wno-format-overflow"
./mach build
}
package() {
cd pmbuild
make package
cd dist
install -d "${pkgdir}"/usr/{bin,lib}
cp -r palemoon/ "${pkgdir}/usr/lib/${pkgname}"
ln -s "../lib/${pkgname}/palemoon" "${pkgdir}/usr/bin/palemoon"
# icons
install -Dm644 palemoon/browser/chrome/icons/default/default16.png \
"${pkgdir}/usr/share/icons/hicolor/16x16/apps/${pkgname}.png"
install -Dm644 palemoon/browser/chrome/icons/default/default32.png \
"${pkgdir}/usr/share/icons/hicolor/32x32/apps/${pkgname}.png"
install -Dm644 palemoon/browser/chrome/icons/default/default48.png \
"${pkgdir}/usr/share/icons/hicolor/48x48/apps/${pkgname}.png"
install -Dm644 palemoon/browser/icons/mozicon128.png \
"${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"
# install desktop file
install -Dm644 "${srcdir}/${_repo}/palemoon/branding/official/palemoon.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|