blob: 4c1ce11cc5ae5bb9981df06da95edf99996478e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Contributor: Zeph <zeph33@gmail.com>
# Maintainer: Zeph <zeph33@gmail.com>
pkgname=pamac-aur
pkgver=2.4.3
_pkgver=2.4.3
pkgrel=5
# This is the release package so the below _gitcommit variable should (usually) be commented out.
_gitcommit="d7d393ed4e265ed0041a287e10306c6cf65971d8"
pkgdesc="A Gtk3 frontend for libalpm"
arch=('any')
url="https://github.com/manjaro/pamac"
license=('GPL3')
depends=('glib2>=2.42' 'json-glib' 'libsoup' 'dbus-glib' 'polkit' 'vte3>=0.38' 'gtk3>=3.16'
'libnotify' 'desktop-file-utils' 'pacman>=4.2' 'gnutls>=3.4')
optdepends=('polkit-gnome: needed for authentification in Cinnamon, Gnome'
'lxsession: needed for authentification in Xfce, LXDE etc.'
'yaourt: needed for AUR support')
makedepends=('gettext' 'itstool' 'vala>=0.28')
backup=('etc/pamac.conf')
provides=('pamac')
conflicts=('pamac')
options=(!emptydirs)
install=pamac.install
if [ "${_gitcommit}" != "" ]; then
source=("pamac-$pkgver-$pkgrel.tar.gz::$url/archive/$_gitcommit.tar.gz")
else
source=("pamac-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
fi
source+=('notification-improvment.patch::https://github.com/manjaro/pamac/pull/88.patch')
sha256sums=('f8534a276a929ffdcc315d15e7a5b04274faacde2714e0a64bf8358b84d355db'
'dabd01fc2315fecd01c85de040bf97f4ba3932343590fa06a95d0a324554d089')
prepare() {
if [ "$_gitcommit" != "" ]; then
mv "$srcdir/pamac-$_gitcommit" "$srcdir/pamac-$pkgver"
fi
# adjust version string
cd "$srcdir/pamac-$pkgver/src"
sed -i -e "s|\"$_pkgver\"|\"$pkgver-$pkgrel\"|g" manager_window.vala
cd "$srcdir/pamac-$pkgver/"
# patches here
patch -Np1 -i $srcdir/notification-improvment.patch
}
build() {
cd "$srcdir/pamac-$pkgver"
# build
make all
}
package() {
cd "$srcdir/pamac-$pkgver"
mkdir -p "${pkgdir}/usr/share/icons/hicolor"
cp -r "data/icons/"* "${pkgdir}/usr/share/icons/hicolor"
cp -r "po/locale" "${pkgdir}/usr/share"
install -Dm744 "src/pamac-daemon" "${pkgdir}/usr/bin/pamac-daemon"
install -Dm755 "src/pamac-manager" "${pkgdir}/usr/bin/pamac-manager"
install -Dm755 "src/pamac-updater" "${pkgdir}/usr/bin/pamac-updater"
install -Dm755 "src/pamac-tray" "${pkgdir}/usr/bin/pamac-tray"
install -Dm755 "src/pamac-refresh" "${pkgdir}/usr/bin/pamac-refresh"
install -Dm755 "src/pamac-install" "${pkgdir}/usr/bin/pamac-install"
install -Dm644 "data/applications/pamac-tray.desktop" "${pkgdir}/etc/xdg/autostart/pamac-tray.desktop"
install -Dm644 "data/applications/pamac-manager.desktop" "${pkgdir}/usr/share/applications/pamac-manager.desktop"
install -Dm644 "data/applications/pamac-updater.desktop" "${pkgdir}/usr/share/applications/pamac-updater.desktop"
install -Dm644 "data/applications/pamac-install.desktop" "${pkgdir}/usr/share/applications/pamac-install.desktop"
install -Dm644 "data/config/pamac.conf" "${pkgdir}/etc/pamac.conf"
install -Dm644 "data/dbus/org.manjaro.pamac.conf" "${pkgdir}/etc/dbus-1/system.d/org.manjaro.pamac.conf"
install -Dm644 "data/dbus/org.manjaro.pamac.service" "${pkgdir}/usr/share/dbus-1/system-services/org.manjaro.pamac.service"
install -Dm644 "data/systemd/pamac.service" "${pkgdir}/usr/lib/systemd/system/pamac.service"
install -Dm744 "data/networkmanager/99_update_pamac_tray" "${pkgdir}/etc/NetworkManager/dispatcher.d/99_update_pamac_tray"
install -Dm644 "data/polkit/org.manjaro.pamac.policy" "${pkgdir}/usr/share/polkit-1/actions/org.manjaro.pamac.policy"
install -Dm644 "data/mime/x-alpm-package.xml" "${pkgdir}/usr/share/mime/packages/x-alpm-package.xml"
}
# vim:set ts=2 sw=2 et:
|