summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: da70f227ca1620b4917510b815a83ea1c58e606f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>

pkgname=pantheon-applications-menu-git
pkgver=2.5.0.r152.13a9269
pkgrel=1
pkgdesc='The Pantheon Application Menu'
arch=(x86_64)
url=https://github.com/elementary/applications-menu
license=(GPL3)
groups=(pantheon-unstable)
depends=(
  appstream
  gdk-pixbuf2
  glib2
  gnome-menus
  gtk3
  json-glib
  lib{gee,granite.so,soup,handy1}
  lib{switchboard,wingpanel}-2.0.so
  zeitgeist
)
makedepends=(
  git
  meson
  granite
  switchboard
  vala
  wingpanel
)
provides=(pantheon-applications-menu)
conflicts=(pantheon-applications-menu)
source=(pantheon-applications-menu::git+https://github.com/elementary/applications-menu.git)
sha256sums=(SKIP)

pkgver() {
  cd pantheon-applications-menu

  git describe --tags | sed 's/-/.r/; s/-g/./'
}

build() {
  arch-meson pantheon-applications-menu build \
    -D b_pie=false \
    -D with-unity=false
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et: