blob: 11cb8a27ad2ad68e6571f68c893133266294ecaf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer: Qiu Wenbo <qiuwenbo@gnome.org>
pkgbase=papers
pkgname=(
papers
papers-lib-docs
)
pkgver=45.0+r484+g4d43a1c7
pkgrel=1
pkgdesc="Document viewer (PDF, PostScript, XPS, djvu, dvi, tiff, cbr, cbz, cb7, cbt)"
url="https://apps.gnome.org/Papers/"
arch=(x86_64)
license=(GPL)
depends=(
dconf
djvulibre
gsettings-desktop-schemas
gsfonts
gst-plugins-base-libs
gtk4
gvfs
libarchive
libgxps
libadwaita
libsecret
libspectre
exempi
poppler-glib
)
makedepends=(
appstream-glib
gi-docgen
git
gobject-introspection
meson
yelp-tools
rust
libnautilus-extension
)
source=("git+https://gitlab.gnome.org/GNOME/Incubator/papers.git#branch=main")
b2sums=('SKIP')
pkgver() {
cd papers
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd papers
}
build() {
local meson_options=(
-D ps=enabled
)
arch-meson papers build "${meson_options[@]}"
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_papers() {
provides=(libpps{document,view}-4.0.so)
groups=(gnome)
meson install -C build --destdir "$pkgdir"
_pick lib-docs "$pkgdir"/usr/share/doc/lib*
}
package_papers-lib-docs() {
pkgdesc+=" (library API documentation)"
depends=()
mv lib-docs/* "$pkgdir"
}
# vim:set sw=2 sts=-1 et:
|