PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

#Maintainer: Erwin-Iosef erwiniosef@gmail.com
#PKGBUILD credit to https://aur.archlinux.org/pkgbase/papirus-icon-theme-git(Thanks!)
pkgname=('papirus-icon-theme-plasma-fork-git' 'epapirus-icon-theme-plasma-fork-git')
pkgver=r7368.e55ae37
pkgrel=4
pkgdesc="Custom fork for Plasma to use Papirus with respect to Colorscheme support."
arch=('any')
url="https://github.com/Erwin-Iosef/papirus-icon-theme-plasma-fork.git"
license=("GPL-3.0-or-later")
depends=('gtk-update-icon-cache')
makedepends=('git')
source=("git+https://github.com/Erwin-Iosef/papirus-icon-theme-plasma-fork.git")
sha256sums=('SKIP')
options+=(!strip)

pkgver() {
  cd "${pkgname%-git}"
  ( set -o pipefail
    git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
  )
}

package_papirus-icon-theme-plasma-fork-git() {
  provides=('papirus-icon-theme')
  conflicts=('papirus-icon-theme')

  cd "${pkgbase%-git}"
  make DESTDIR="$pkgdir" ICON_THEMES="Papirus" install
}

package_epapirus-icon-theme-plasma-fork-git() {
  pkgdesc+=" (for elementary OS and Pantheon Desktop only)"
  depends+=('papirus-icon-theme-plasma-fork-git')
  provides=('epapirus-icon-theme')
  conflicts=('epapirus-icon-theme')

  cd "${pkgbase%-git}"
  make DESTDIR="$pkgdir" ICON_THEMES="ePapirus" install
}