PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
# Contributor: Siavash Askari Nasr <ciavash@proton.me>
# Contributor: Vladimir Svyatski <vsvyatski@yandex.ru>
# Contributor: Dimitris Kiziridis <ragouel@outlook.com>
# Contributor: EatMyVenom <eat.my.venomm@gmail.com>
# Contributor: Uncle Hunto <unclehunto@yahoo.com>
# Contributor: Limao Luo <luolimao+AUR@gmail.com>
# Contributor: TuxSpirit <tuxspirit@archlinux.fr>
# Contributor: Jamesjon <universales@protonmail.com>

pkgname=peazip-qt-bin
pkgver=10.4.0
pkgrel=1
pkgdesc='PeaZip file manager and archiver (binary release)'
url='https://github.com/peazip/PeaZip'
license=('LGPL-3.0-or-later')
arch=('x86_64')
depends=('7zip' 'brotli' 'hicolor-icon-theme' 'libx11' 'qt6pas' 'upx' 'zstd')
options=('!emptydirs')
provides=("peazip")
conflicts=("peazip")
source=("$url/releases/download/$pkgver/peazip-$pkgver.LINUX.Qt6-1.x86_64.rpm")
sha256sums=('f9b99f136d78ca867fb5ad18b5c180cebb3afa73b9d23060b81aa41029ad4d42')

prepare() {
  cd usr/share/peazip
  rm -r lang-wincontext
  rm -r batch/{Windows,'macOS service menus',bat}
  rm -r batch/freedesktop_integration/KDE-servicemenus/{KDE3*,KDE4*}
  rm icons/peazip_seven.icl
  rm readme/readme_{Windows,macOS}.txt
  cd "$srcdir/usr/lib/peazip/res/bin"
  mkdir -p upx
  ln -sf /usr/bin/7z 7z/7z
  ln -sf /usr/lib/7zip/7zCon.sfx 7z/7zCon.sfx
  ln -sf /usr/bin/brotli brotli/brotli
  ln -sf /usr/bin/upx upx/upx
  ln -sf /usr/bin/zstd zstd/zstd
  rm 7z/7z.sfx
  chmod -x 7z/Codecs/*.so
}

package() {
  mkdir -p "$pkgdir/usr/"{bin,lib/peazip,share/{doc/peazip,peazip,licenses/peazip,icons/hicolor/256x256/apps}}
  cd usr
  mv bin/peazip "$pkgdir/usr/bin"
  install -Dm755 lib/peazip/{peazip,pea} "$pkgdir/usr/lib/peazip"
  mv lib/peazip/res "$pkgdir/usr/lib/peazip"
  cd share
  mv applications "$pkgdir/usr/share"
  mv pixmaps/* "$pkgdir/usr/share/icons/hicolor/256x256/apps"
  cd peazip
  mv peazip_help.pdf "$pkgdir/usr/share/doc/peazip"
  mv copying/* "$pkgdir/usr/share/licenses/peazip"
  mv readme/readme_Linux.txt "$pkgdir/usr/share/doc/peazip/readme.txt"
  rm -r readme
  mv ../peazip "$pkgdir/usr/share"
  ln -s /usr/lib/peazip/pea "$pkgdir/usr/bin"
}