blob: 5a234099df1f1ee0a7ea2d9d0eea87b1499e4941 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Moritz Bunkus <moritz@bunkus.org>
pkgname="perl-algorithm-checkdigits"
pkgver="1.3.6"
pkgrel='1'
pkgdesc="Perl extension to generate and test check digits"
arch=('any')
url="https://metacpan.org/release/Algorithm-CheckDigits"
license=('GPL' 'PerlArtistic')
depends=('perl-module-build' 'perl-probe-perl')
makedepends=('perl-module-build>=0.38' 'perl-probe-perl')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/M/MA/MAMAWE/Algorithm-CheckDigits-v${pkgver}.tar.gz")
sha512sums=('cb9cd318070220f5658ee2d2539d7dc5eb8a47f47c3f2274f4e9fd87f98d4f4f14a8e5d23bfb8b589c477fb1514964b0c9f92fd8d21792ab6b36d62939ba5e70')
prepare_environment() {
export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "${srcdir}/Algorithm-CheckDigits-v${pkgver}"
}
build() {
prepare_environment
/usr/bin/perl Makefile.PL
make
}
check() {
prepare_environment
make test
}
package() {
prepare_environment
make install
find "$pkgdir" "(" -name .packlist -o -name perllocal.pod ")" -delete
}
# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
|