blob: 93662a9701eadbd48cdedcecb316426bd5ae2d70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: marmis <tiagodepalves@gmail.com>
# Contributor: arojas <arojas@archlinux.org>
# Contributor: Florian Pritz <bluewind@archlinux.org>
pkgname=perl-log-any
pkgver=1.718
pkgrel=1
pkgdesc='Bringing loggers and listeners together'
arch=('any')
url="https://metacpan.org/dist/Log-Any"
license=('GPL-1.0-or-later OR Artistic-1.0-Perl')
# See https://metacpan.org/dist/Log-Any/source/Makefile.PL
makedepends=(
## CONFIGURE_REQUIRES
'perl-extutils-makemaker'
)
depends=(
## PREREQ_PM
)
checkdepends=(
## TEST_REQUIRES
'perl-extutils-makemaker'
'perl-pathtools' # "File::Spec"
'perl-io' # "IO::Handle"
'perl' # "IPC::Open3"
'perl-test-simple' # "Test::More"
)
options=('!emptydirs' 'purge')
source=("https://cpan.metacpan.org/authors/id/P/PR/PREACTION/Log-Any-${pkgver}.tar.gz")
b2sums=('bbf9418026fbc301df7cec3c7a52027215fc7737e1c7678a6a0ae0040143398173e67b0b6c249359490956554e942458a3ae923b060c212b35de08e2cf1af256')
build() {
cd "${srcdir}/Log-Any-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
perl Makefile.PL NO_PACKLIST=true NO_PERLLOCAL=true INSTALLDIRS=vendor
make
}
check() {
cd "${srcdir}/Log-Any-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1
make test
}
package() {
cd "${srcdir}/Log-Any-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
make install DESTDIR="${pkgdir}"
}
|