blob: de4ae3467ff182be77c96f634bf21c6d890c890c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Jimmy Xu <me at jimmyxu dot org>
_perlmod='Mail-Milter-Authentication'
_modnamespace=Mail
pkgname=perl-mail-milter-authentication
pkgver=3.20240205
pkgrel=1
pkgdesc="A Perl Mail Authentication Milter"
arch=("any")
url="http://search.cpan.org/dist/$_perlmod"
license=('GPL' 'PerlArtistic')
depends=('perl' 'perl-app-cmd' 'perl-clone' 'perl-date-manip' 'perl-email-date-format' 'perl-email-sender' 'perl-email-simple' 'perl-import-into' 'perl-json' 'perl-list-moreutils' 'perl-lock-file' 'perl-log-dispatchouli' 'perl-mail-authenticationresults' 'perl-mail-bimi' 'perl-mail-datafeed-abusix' 'perl-mail-dkim' 'perl-mail-dmarc' 'perl-mail-spf' 'perl-net-dns' 'perl-net-ip' 'perl-net-server' 'perl-proc-processtable' 'perl-prometheus-tiny-shared>=0.011' 'perl-super' 'perl-test-file-contents' 'perl-test-perl-critic' 'perl-text-table' 'perl-toml')
makedepends=('perl-crypt-openssl-rsa' 'perl-file-sharedir-install' 'perl-test-exception')
checkdepends=('perl-eval-closure' 'perl-namespace-autoclean' 'perl-net-dns-resolver-mock' 'perl-params-validationcompiler' 'perl-specio')
replaces=('perl-mail-milter-authentication-handler-arc')
conflicts=('perl-mail-milter-authentication-handler-arc')
backup=('etc/authentication_milter.json')
options=('!emptydirs')
source=("http://cpan.perl.org/modules/by-module/$_modnamespace/$_perlmod-$pkgver.tar.gz"
'authentication_milter.service')
sha256sums=('88a04406509c2f6a2b1b718b1ca250dc4e86f783343ceeb6cd6eac00ed4d0d7e'
'8715d45d62859fb3838d0fd31878d59b47da2cb62d55675f828f8b812845526d')
build() {
cd "$srcdir/$_perlmod-$pkgver"
# Install module in vendor directories.
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make
}
check() {
cd "$srcdir/$_perlmod-$pkgver"
# Install module in vendor directories.
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make test
}
package() {
cd "$srcdir/$_perlmod-$pkgver"
make install DESTDIR="$pkgdir/"
install -Dm644 "$srcdir/authentication_milter.service" "$pkgdir/usr/lib/systemd/system/authentication_milter.service"
}
# vim:set ts=2 sw=2 et:
|