blob: 7eae0138eeca36457bc911e1f597531ca965a5a3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: FlorianNAdam
_pkgname=persistent-evdev-rs
pkgname=persistent-evdev-rs-git
pkgver=r9.a39594a
pkgrel=1
pkgdesc="Persistent proxy for evdev devices"
arch=("x86_64")
url="https://github.com/FlorianNAdam/persistent-evdev-rs"
license=("MIT")
provides=("persistent-evdev-rs")
conflicts=("persistent-evdev-rs")
makedepends=(cargo)
source=('git+https://github.com/FlorianNAdam/persistent-evdev-rs')
sha256sums=('SKIP')
backup=(
"etc/persistent-evdev-rs/config.json"
)
pkgver() {
cd ${_pkgname}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd ${_pkgname}
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd ${_pkgname}
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd ${_pkgname}
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd ${_pkgname}
install -Dm755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
install -Dm644 config.json "$pkgdir/etc/persistent-evdev-rs/config.json"
install -Dm644 systemd/persistent-evdev-rs.service "$pkgdir/usr/lib/systemd/system/persistent-evdev-rs.service"
install -Dm644 udev/60-persistent-input-rs-uinput.rules "$pkgdir/usr/lib/udev/rules.d/60-persistent-input-rs-uinput.rules"
}
|