1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Maintainer: Auto update bot <auto-update-bot@jingbei.li>
# Maintainer: Jingbei Li <i@jingbei.li>
# Contributor: Sigvald Marholm <marholm@marebakken.com>
# Adapted from the package petsc with the following original contributors:
# Contributor: Martin Diehl <https://martin-diehl.net>
# Contributor: Andreas Bilke <abilke at cosy dot sbg dot ac dot at>
# Contributor: Myles English <myles at rockhead dot biz>
# Contributor: Lucas H. Gabrielli <heitzmann at gmail dot com>
_base=petsc
pkgname=${_base}-complex
pkgver=3.21.1
pkgrel=1
_config=linux-c-opt
# if --with-debugging=yes is set then PETSC_ARCH is automatically set to
#"linux-c-debug" for some things, so the _config should be changed too
#_config=linux-c-debug
pkgdesc="Portable, extensible toolkit for scientific computation (complex scalars)"
arch=(i686 x86_64)
url="https://${_base}.org"
license=(BSD-2-Clause)
options=(staticlibs)
conflicts=(${_base})
provides=("${_base}=${pkgver}")
depends=(hdf5-openmpi fftw-openmpi gsl lapack libjpeg-turbo libyaml netcdf-openmpi
python-numpy python-mpi4py superlu suitesparse zlib)
makedepends=(cmake cython gcc gcc-fortran)
checkdepends=()
optdepends=('hypre: support for the hypre sparse system solver'
'kokkos: support for Kokkos'
'metis: support for metis graph partitioning library'
'mumps: support for the mumps sparse solver'
'parmetis: support for parmetis parallel graph partitioning library'
'pastix: support for the pastix solver'
'scalapack: support for ScaLAPACK'
'scotch: support for Scotch'
'superlu_dist: support for the superlu_dist sparse solver'
'triangle: support for the two-dimensional quality mesh generator and Delaunay triangulator'
'valgrind: support for valgrind to help find memory-management problems in programs'
'zoltan: support for zoltan')
install=${_base}.install
source=(https://web.cels.anl.gov/projects/${_base}/download/release-snapshots/${_base}-lite-${pkgver}.tar.gz
test_optdepends.sh)
sha512sums=('ae65afd9cff1eb33a4c7688b53d83427edf1b6866eca4879ea0fd1e7f03167906664f4b250901f37406e88e1ba43f1f7a38651c27dd367fc42e5e80a66ae8469'
'1a790c36b1bb6b6604b4fe35f3c7fba2d8f972e7fd3c6ac1273716bee490f4dded18990b9f4aedecbe609aa6ec3d2469d44c013e18ed5cf9a43f5703f2b59db8')
_install_dir=/opt/${_base}/${_config}
_petsc_arch=arch-${_config}
build() {
_build_dir=${srcdir}/${_base}-${pkgver}
cd ${_build_dir}
export PETSC_ARCH=${_petsc_arch}
export PETSC_DIR=${_build_dir}
OPTFLAGS='-O3 -march=native'
CONFOPTS="--with-shared-libraries=1 \
--with-mpi-f90module-visibility=0 \
--with-petsc4py=1 \
--with-mpi-dir=/usr \
--with-zfp=0 \
--with-netcdf=1 \
--with-libjpeg=1 \
--with-yaml=1 \
--with-fftw=1 \
--with-gsl=1 \
--with-zlib=1 \
--with-superlu-lib=-lsuperlu --with-superlu-include=/usr/include/superlu \
--with-suitesparse-include=/usr/include/suitesparse \
--with-suitesparse-lib=[libamd.so,libbtf.so,libcamd.so,libccolamd.so,libcholmod.so,libcolamd.so,libcxsparse.so,libgraphblas.so,libklu.so,libklu_cholmod.so,liblagraph.so,liblagraphx.so,libldl.so,libparu.so,librbio.so,libspex.so,libspqr.so,libsuitesparse_mongoose.so,libsuitesparseconfig.so,libumfpack.so] \
--with-hdf5=1 --with-hdf5-fortran-bindings=1 \
--with-scalar-type=complex \
$(sh ${srcdir}/test_optdepends.sh)"
echo ${CONFOPTS}
python ./configure --prefix=${_install_dir} ${CONFOPTS} \
--COPTFLAGS=${OPTFLAGS} --CXXOPTFLAGS=${OPTFLAGS} --FOPTFLAGS=${OPTFLAGS}
make ${MAKEFLAGS} all
make DESTDIR=${srcdir}/tmp install
}
check() {
cd ${srcdir}/${_base}-${pkgver}
PYTHONPATH=${srcdir}/tmp/${_install_dir}/lib:${PYTHONPATH} make check
}
package() {
_build_dir=${srcdir}/${_base}-${pkgver}
mkdir -p ${pkgdir}/${_install_dir}
cp -Hr ${srcdir}/tmp/* ${pkgdir}
# install licence (even though there is no such word as licenses)
install -Dm 644 ${_build_dir}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
mkdir -p ${pkgdir}/etc/profile.d
echo export PETSC_DIR=${_install_dir} >${pkgdir}/etc/profile.d/petsc.sh
echo export PYTHONPATH=${_install_dir}/lib:'${PYTHONPATH}' >>${pkgdir}/etc/profile.d/petsc.sh
chmod +x ${pkgdir}/etc/profile.d/petsc.sh
# show where the shared libraries are
install -dm 755 "${pkgdir}"/etc/ld.so.conf.d/
echo ${_install_dir}/lib >${pkgdir}/etc/ld.so.conf.d/petsc.conf
# install pkgconfig settings
install -Dm 644 ${_build_dir}/${_petsc_arch}/lib/pkgconfig/PETSc.pc ${pkgdir}/usr/share/pkgconfig/PETSc.pc
}
|