blob: 3d3202827d9c4c5431187b91c83ec698bf253874 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andreas Schönfelder <passtschu at freenet dot de>
pkgname=phoronix-test-suite-milestone
pkgver=10.4.0m1
pkgrel=1
pkgdesc="The most comprehensive testing and benchmarking platform available for Linux, milestone version"
arch=(any)
license=(GPL3)
url="http://www.phoronix-test-suite.com/"
depends=(php)
makedepends=(git)
optdepends=('php-gd'
'sqlite3: required when running a Phoromatic server.'
'gcc-fortran: required for universe-cli test suite'
'blas: required for universe-cli test suite'
'lapack: required for universe-cli test suite'
'portaudio: required for universe-cli test suite'
'unzip: required for universe-cli test suite'
'mesa-demos: required for universe-cli test suite'
'openmpi: required for universe-cli test suite')
provides=(phoronix-test-suite)
conflicts=(phoronix-test-suite)
source=("git+https://github.com/phoronix-test-suite/phoronix-test-suite.git#tag=v${pkgver}"
"https://raw.githubusercontent.com/FabioLolix/AUR-artifacts/master/phoronix-test-suite-launcher.patch")
sha256sums=('SKIP'
'577326343d0303a59fd469c3f9c9740e756dd59c0660c54363b62d6fd1cee26d')
options=(!strip)
prepare() {
cd "${srcdir}/phoronix-test-suite"
patch phoronix-test-suite -i "${srcdir}/phoronix-test-suite-launcher.patch"
}
package() {
cd "${srcdir}/phoronix-test-suite"
./install-sh "$pkgdir/usr"
rm -r "${pkgdir}"/usr/share/phoronix-test-suite/deploy
rm -rf "${pkgdir}"/usr/share/phoronix-test-suite/pts-core/external-test-dependencies/{dependency-handlers,scripts,xml}/{*.php,*.sh,*.xml}
install -D "${srcdir}/phoronix-test-suite"/pts-core/external-test-dependencies/dependency-handlers/arch_dependency_handler.php \
"${pkgdir}"/usr/share/phoronix-test-suite/pts-core/external-test-dependencies/dependency-handlers/arch_dependency_handler.php
install -D "${srcdir}/phoronix-test-suite"/pts-core/external-test-dependencies/scripts/install-arch-packages.sh \
"${pkgdir}"/usr/share/phoronix-test-suite/pts-core/external-test-dependencies/scripts/install-arch-packages.sh
install -D "${srcdir}/phoronix-test-suite"/pts-core/external-test-dependencies/xml/arch-packages.xml \
"${pkgdir}"/usr/share/phoronix-test-suite/pts-core/external-test-dependencies/xml/arch-packages.xml
install -D "${srcdir}/phoronix-test-suite"/pts-core/external-test-dependencies/xml/generic-packages.xml \
"${pkgdir}"/usr/share/phoronix-test-suite/pts-core/external-test-dependencies/xml/generic-packages.xml
ln -s /usr/bin/phoronix-test-suite "${pkgdir}/usr/bin/pts"
}
|