blob: c0fa924a5ead11f409d264ec154b921ef000c00f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Olav Seyfarth <php-legacy-mailparse at seyfarth dot de>
# Contributor: Thomas Gerbet <thomas at gerbet dot me>
# Contributor: Johannes Schleifenbaum <johannes at js-webcoding dot de>
pkgname=php-legacy-mailparse
pkgver=3.1.6
pkgrel=1
pkgdesc="Extension for parsing and working with email messages (RFC822 and RFC2045)"
arch=('i686' 'x86_64')
url="https://pecl.php.net/package/mailparse"
license=('PHP')
depends=('php-legacy>=8.2.0')
backup=('etc/php-legacy/conf.d/mailparse.ini')
source=("https://pecl.php.net/get/mailparse-${pkgver}.tgz"
'mailparse.ini')
sha256sums=('a69f1605583eabdb59c2cd4c17334b3267398a1d47e1fd7edb92d8bef9dee008'
'0d66498ce1dee28ff447e20cfcb9abff50469fed0ce412898cde41dec4a7828a')
build() {
cd "${srcdir}/mailparse-${pkgver}/"
phpize-legacy
./configure --prefix=/usr
make
}
check() {
cd "${srcdir}/mailparse-${pkgver}/"
export REPORT_EXIT_STATUS=1
export NO_INTERACTION=1
export SKIP_ONLINE_TESTS=1
make test
}
package() {
cd "${srcdir}/mailparse-${pkgver}/"
make INSTALL_ROOT="${pkgdir}/" install
install -D -m 644 "$srcdir"/mailparse.ini "$pkgdir"/etc/php-legacy/conf.d/mailparse.ini
}
|