summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b7ccd1ba0cf30f676aa4fbbb744c0ffb62aa915c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Boris Momčilović <boris.momcilovic@gmail.com>

_pkgname=nocheq
pkgname=php-$_pkgname-git
pkgver=r40.334fd74
pkgrel=1
pkgdesc="Sick of pesky type checking making your code too slow (and correct) ?"
arch=('i686' 'x86_64')
url="https://github.com/kornrunner/nocheq"
license=('PHP')
depends=('php')
makedepends=('git')
source=(git+https://github.com/kornrunner/nocheq.git)
md5sums=('SKIP')
_ininame="nocheq.ini"
_inifile="etc/php/conf.d/$_ininame"
backup=("$_inifile")

pkgver() {
  cd "$_pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/$_pkgname"

  phpize
  ./configure --prefix=/usr
  make
  #TEST_PHP_EXECUTABLE=`which php` php run-tests.php
}

package() {
  cd "$srcdir/$_pkgname"
  make PREFIX=/usr INSTALL_ROOT="$pkgdir" install
  cat >> "$_ininame" <<EOF
;extension=nocheq.so
EOF

  install -vDm644 "$_ininame" "$pkgdir/$_inifile"
}