PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer:

_gitname="runkit7"
_pkgname="php-$_gitname"
pkgname="$_pkgname-git"
pkgdesc='Tools to allow what Reflection does not. Useful for unit tests.'
pkgver=4.0.0a6.r1.g8ffec37
pkgrel=1

arch=('x86_64' 'i686')
license=('PHP')
url="https://github.com/runkit7/runkit7"

depends=('php')
makedepends=('git')

provides=(
  "$_pkgname"
  'php-runkit'
)
conflicts=(${provides[@]})

source=(
  "$_gitname"::"git+$url"
)
sha256sums=(
  'SKIP'
)

pkgver() {
  cd "$srcdir/$_gitname"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/$_gitname"
  phpize
  ./configure
  make
}

package() {
  cd "$srcdir/$_gitname"
  install -vDm0644 "$srcdir/$_gitname/modules/$_gitname.so" "$pkgdir/usr/lib/php/modules/$_gitname.so"

  echo "extension=$_gitname.so" > "$srcdir/$_gitname.ini"
  echo "$_gitname.internal_override=1" >> "$srcdir/$_gitname.ini"
  install -vDm0644 "$srcdir/$_gitname.ini" -t "$pkgdir}/etc/php/conf.d"
}