blob: c988c110b7f940efb83e489071d26c16de0f095a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Timo Sarawinski <timo@it-kraut.net>
_name=igbinary
pkgname=php80-igbinary
pkgver=3.2.14
pkgrel=1
pkgdesc="A drop in replacement for the standard php serializer (PHP 8.0)"
arch=('x86_64')
url="https://github.com/igbinary/igbinary"
license=('BSD')
depends=('glibc')
makedepends=('php80' 'php80-cli' )
backup=("etc/php80/conf.d/${_name}.ini")
source=("$pkgname-$pkgver.tar.gz::https://github.com/${_name}/${_name}/archive/${pkgver}.tar.gz")
sha512sums=('8f58817b86c560bd81344ec51260d31b02868584254d6b94b44e07ea5371ddebfc2ccee7bc56ca1ad5873bdbb758fc95683555e7c5abf5d69db9d962bf0e88b3')
b2sums=('17cb77a68e2458021563ae288fccbd49132b04f9b5e2a27b7dbfc2c851536d30b813fcf4cc48684afda0cd3e3b0c2c915b13b668d85715d827bee86a4c499573')
prepare() {
mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
cd "$pkgname-$pkgver"
# disable the extension by default
sed 's/extension/;extension/g' -i "${_name}.php.ini"
phpize80
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --enable-igbinary
make
}
check() {
cd "$pkgname-$pkgver"
export TEST_PHPDBG_EXECUTABLE=/usr/bin/phpdbg80
NO_INTERACTION=1 make -k test
}
package() {
cd "$pkgname-$pkgver"
make INSTALL_ROOT="$pkgdir/" install
install -vDm 644 "${_name}.php.ini" "${pkgdir}/etc/php80/conf.d/${_name}.ini"
install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -vDm 644 {CREDITS,NEWS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|