blob: 163326d3c6619435b5319343702ec7a52d6662af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Contributor: Mettacrawer <metta.crawler@gmail.com>
# Contributor: luizribeiro <luizribeiro@gmail.com>
# Maintainer: max.bra <max dot bra dot gtalk at gmail dot com>
# Maintainer: graysky <therealgraysky AT protonmail DOT com>
pkgname=pi-hole-ftl
_pkgname=FTL
_servicename=pihole-FTL
pkgver=6.1
pkgrel=1
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
pkgdesc="The Pi-hole FTL engine"
url="https://github.com/pi-hole/FTL"
license=('EUPL-1.2')
depends=('nettle' 'gmp' 'mbedtls' 'pi-hole-web')
makedepends=('cmake' 'xxd')
conflicts=('dnsmasq')
provides=('dnsmasq')
install=$pkgname.install
backup=('etc/pihole/pihole-FTL.conf' 'etc/pihole/dhcp.leases')
source=($pkgname-v$pkgver.tar.gz::"https://github.com/pi-hole/FTL/archive/v$pkgver.tar.gz"
"https://raw.githubusercontent.com/max72bra/pi-hole-ftl-archlinux-customization/master/arch-ftl-$pkgver-$pkgrel.patch"
"$pkgname.tmpfile"
"$pkgname.sysuser"
"$pkgname.service")
sha256sums=('a4d7f7d905dd36ffa2855e4a917629611cb8e95c4783c67ef19b150652a87f1f'
'2d23644e474bad63f0959527d19d988f3307e52903918545278cfb310545779c'
'0feb4597a4afd9054553505d305b0feb7e1f6e1705b092561648ff37d0a2893c'
'dd1d2a341e774d4e549373ae75604031b9af0ee44debcd71a89259d9110d2a77'
'0998da040d038ddbad129ba8e1ea74741bc912813407b579cab1b3b3f206e721')
prepare() {
cd "$srcdir"/"$_pkgname"-"$pkgver"
patch -Np1 -i "$srcdir"/arch-ftl-$pkgver-$pkgrel.patch
}
build() {
cd "$srcdir"/"$_pkgname"-"$pkgver"
STATIC=false ./build.sh
}
package() {
cd "$srcdir"
install -Dm775 "$_pkgname"-$pkgver/pihole-FTL "${pkgdir}"/usr/bin/pihole-FTL
install -Dm644 "$pkgname.tmpfile" "$pkgdir"/usr/lib/tmpfiles.d/$pkgname.conf
install -Dm644 "$pkgname.sysuser" "$pkgdir"/usr/lib/sysusers.d/$pkgname.conf
install -dm755 "$pkgdir"/etc/pihole
install -Dm664 /dev/null "$pkgdir"/etc/pihole/dhcp.leases
install -Dm644 "$pkgname.service" "$pkgdir"/usr/lib/systemd/system/$_servicename.service
install -dm755 "$pkgdir/usr/lib/systemd/system/multi-user.target.wants"
ln -s ../$_servicename.service "$pkgdir/usr/lib/systemd/system/multi-user.target.wants/$_servicename.service"
install -dm755 "$pkgdir"/usr/share/licenses/pihole
install -Dm644 "$_pkgname"-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/pihole/Pi-hole-FTL
# ver. 5.0+ dnamasq dropin support
ln -s ./pihole-FTL "$pkgdir/usr/bin/dnsmasq"
}
|