blob: 0e354c0aa4da054d6d316bdd5b20e4c5915c1a3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: schuay <jakob.gruber@gmail.com>
pkgname=picmi-git
pkgver=24.01.90.r22.gcb668b9
pkgdesc="A nonogram logic game for KDE"
pkgrel=1
epoch=1
arch=('x86_64')
url="https://apps.kde.org/picmi/"
license=('GPL-2.0-or-later' 'LGPL-2.0-or-later')
depends=('gcc-libs'
'glibc'
'kconfigwidgets'
'kcoreaddons'
'kcrash'
'kdbusaddons'
'ki18n'
'kwidgetsaddons'
'kxmlgui'
'libkdegames'
'qt6-base'
'qt6-svg')
makedepends=('extra-cmake-modules' 'git' 'kdoctools')
conflicts=('picmi')
provides=('picmi')
source=("git+https://invent.kde.org/games/picmi.git")
sha256sums=('SKIP')
pkgver() {
git -C picmi describe --tags | sed 's/^v//;s/-/.r/;s/-/./g'
}
build() {
cmake -B build -S picmi \
-DBUILD_TESTING=OFF
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
# vim:set ts=2 sw=2 et:
|