blob: 38bccd8e7120e2e9fab69cea37b655b2a4b1192c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Joe Groocock <aur@frebib.net>
# Contributor: WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor: OK100 <ok100 at lavabit dot com>
# Contributor: Valère Monseur <valere dot monseur at ymail dot com>
pkgname=picom-tryone-git
_gitname=compton
pkgver=1298_0.1_beta2.949.gf92eb6b_2019.12.21
pkgrel=1
pkgdesc="tryone144's picom fork with dual_kawase blur, an X compositor (fork of compton)"
arch=(i686 x86_64)
url="https://github.com/tryone144/${_gitname}"
license=('MIT' 'MPL2')
depends=('libgl' 'libev' 'pcre' 'libx11' 'xcb-util-renderutil' 'libxcb' 'xcb-util-image' 'libxext'
'pixman' 'libconfig' 'libdbus' 'hicolor-icon-theme' 'libxdg-basedir')
makedepends=('git' 'mesa' 'meson' 'asciidoc' 'uthash')
optdepends=('dbus: To control picom via D-Bus'
'xorg-xwininfo: For picom-trans'
'xorg-xprop: For picom-trans'
'python: For picom-convgen.py')
provides=('compton' 'compton-git' 'picom' 'picom-git')
conflicts=('compton' 'compton-git' 'picom' 'picom-git')
replaces=('compton-git' 'picom-git')
options=('!strip')
source=(git+"https://github.com/tryone144/${_gitname}.git#branch=feature/dual_kawase")
md5sums=("SKIP")
pkgver() {
cd ${_gitname}
_tag=$(git describe --tags | sed 's:^v::') # tag is mobile, and switches between numbers and letters, can't use it for versioning
_commits=$(git rev-list --count HEAD) # total commits is the most sane way of getting incremental pkgver
_date=$(git log -1 --date=short --pretty=format:%cd)
printf "%s_%s_%s\n" "${_commits}" "${_tag}" "${_date}" | sed 's/-/./g'
}
build() {
cd "${srcdir}/${_gitname}"
meson --buildtype=debug . build --prefix=/usr -Dwith_docs=true
ninja -C build
}
package() {
cd "${srcdir}/${_gitname}"
DESTDIR="${pkgdir}" ninja -C build install
# install license
install -D -m644 "LICENSES/MIT" "${pkgdir}/usr/share/licenses/${pkgname/-git$/}/LICENSE-MIT"
# example conf
install -D -m644 "picom.sample.conf" "${pkgdir}/etc/xdg/picom.conf.example"
}
|