blob: fd689cca6e55dd698dacd76742f62e4b4b546885 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
pkgname=pipdeptree
pkgver=2.18.1
pkgrel=1
arch=(any)
pkgdesc='Command line utility to show dependency tree of Python packages'
url='https://github.com/naiquevin/pipdeptree'
depends=(python-packaging python-pip)
makedepends=(python-build python-hatchling python-hatch-vcs python-installer python-wheel)
optdepends=('python-graphviz: for generating graphical output')
license=(MIT)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('cb6cacc5434dc04811bdc91d659622689107e60a163b79a5758e593577fdb875')
prepare() {
cd $pkgname-$pkgver
sed -E -i -e 's|hatchling>=[^"]+|hatchling|' pyproject.toml
}
build() {
cd $pkgname-$pkgver
python -m build --wheel --no-isolation
}
package() {
cd $pkgname-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
# install documentation
install -Dm644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
# install license
install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}
# vim:set ts=2 sw=2 et:
|