PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Iván Zaera Avellón <ivan.zaera@posteo.net>
pkgname=plumero
pkgver=0.0.2
pkgrel=1
pkgdesc='A command line tool to tidy up home and /etc folders.'
arch=('pentium4' 'x86_64')
url='https://codeberg.org/ivan.zaera/plumero'
license=('GPL-3.0-or-later')
depends=(
	'bash'
	'coreutils'		# cut, printf, tail
	'findutils'		# find
	'grep'
	'ncurses'		# tput
	'pacman'
)
makedepends=(
	'coreutils'
	'scdoc'
)
backup=(
	etc/plumero/config
)
install='install.sh'

source=(
	"$pkgname-$pkgver.tar.gz::https://codeberg.org/ivan.zaera/$pkgname/archive/$pkgver.tar.gz"
)
sha256sums=("a0372299f56b6f27b231044bd7a12d492fe734f6eabbf565acff97bad17bd328")

build() {
	cd $srcdir/$pkgname
	make MODE=release build
}

check() {
	cd $srcdir/$pkgname
	make lint
	make test
}

package() {
	cd $srcdir/$pkgname

	cp -arv root/* $pkgdir
	# cp -arv arch/root/* $pkgdir

	mkdir -p $pkgdir/usr/bin
	cp -arv bash/plumero $pkgdir/usr/bin/plumero

	mkdir -p $pkgdir/usr/lib/plumero
	cp -arv bash/*.bash $pkgdir/usr/lib/plumero

	mkdir -p $pkgdir/usr/share/man/man1
	cp -arv man/build/plumero.1.gz $pkgdir/usr/share/man/man1
}