blob: 35d0200d98364915b5b369a692bbd21c2dac7c8d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Scott Lawrence <bytbox@gmail.com>
# Forked from pommed. Previous header:
# Maintainer: Corrado Primier <ilbardo gmail com>
# Contributor: Other contributors existed but lost information
# Contributor: dpevp <daniel.plaza.espi@gmail.com>
# Contributor: jordi Cerdan (jcerdan) <jcerdan@tecob.com>
pkgname=pommed-light
pkgver=1.52lw
pkgrel=1
pkgdesc="Handles the hotkeys of Apple MacBook (Pro) laptops - lightweight edition"
arch=('i686' 'x86_64')
url="https://github.com/bytbox/pommed-light"
license=('GPL2')
install=$pkgname.install
makedepends=('pkgconfig')
depends=('alsa-lib' 'pciutils' 'confuse' 'audiofile')
conflicts=('pommed')
optdepends=('eject: disc ejection support')
source=(https://github.com/bytbox/${pkgname}/archive/v${pkgver}.tar.gz pommed.service)
dfname="${pkgname}-${pkgver}"
sha256sums=('18b18a2a1b557d31c871059464123435b752615880e0fad085212f01d7099187'
'22cc70a00e995d3f42b08b2ac5c44f7acadeaa5b8bd287863d3e51b115a1151e')
build() {
cd ${srcdir}/${dfname}
make pommed
}
package() {
install -Dm755 ${srcdir}/${dfname}/pommed/pommed ${pkgdir}/usr/bin/pommed
install -Dm644 ${srcdir}/${dfname}/pommed.conf.mactel ${pkgdir}/etc/pommed.conf.mactel
install -Dm644 ${srcdir}/${dfname}/pommed.conf.pmac ${pkgdir}/etc/pommed.conf.pmac
# Man page
install -Dm644 ${srcdir}/${dfname}/pommed.1 ${pkgdir}/usr/share/man/man1/pommed.1
# Sounds
install -Dm644 ${srcdir}/${dfname}/pommed/data/goutte.wav ${pkgdir}/usr/share/pommed/goutte.wav
install -Dm644 ${srcdir}/${dfname}/pommed/data/click.wav ${pkgdir}/usr/share/pommed/click.wav
# Systemd
install -Dm644 ${srcdir}/pommed.service ${pkgdir}/usr/lib/systemd/system/pommed.service
}
# vim:set ts=2 sw=2 et:
|