blob: 47e279a7e784e140e72ed33a4231a10398365f46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: D. Can Celasun <can[at]dcc[dot]im>
pkgname=ponscripter-sekaiproject
_pkgname=ponscripter
pkgver=v3.0.0
pkgrel=4
pkgdesc="Sekai Project Fork (07th-Mod) of the Ponscripter visual novel engine to take advantage of SDL2 and improve Steam integration"
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/07th-mod/ponscripter-fork"
license=('GPL')
depends=('sdl2_mixer' 'sdl2_image' 'freetype2' 'gcc-libs' 'smpeg2')
makedepends=('libmodplug')
source=("${_pkgname}::git+https://github.com/07th-mod/ponscripter-fork.git#tag=${pkgver}")
md5sums=('SKIP')
provides=('ponscripter')
conflicts=('ponscripter')
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --tags
}
build() {
cd "${srcdir}/${_pkgname}/"
# Doesn't work without this
cp /usr/include/libmodplug/modplug.h src/extlib/src/SDL2_mixer-2.0.0
sed -i "36i\#include <unistd.h>" ./src/AnimationInfo.h
./configure --prefix=/usr --no-werror \
--disable-internal-libs \
--disable-internal-sdl \
--disable-internal-sdlimage \
--with-external-sdl-mixer \
--disable-internal-bz \
--disable-internal-smpeg
make
}
package() {
install -D -m755 "${srcdir}/${_pkgname}/src/ponscr" "${pkgdir}/usr/bin/${_pkgname}"
install -dm755 "${pkgdir}/usr/share/doc/${pkgname}"
cd "${srcdir}/${_pkgname}"
install -m644 BUGS CHANGES INSTALL.md MANUAL README.md TODO "${pkgdir}/usr/share/doc/${pkgname}"
}
|