blob: 3f3ea286914a62bbd1a069f9d4fbb42f42d89846 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=('pop-launcher-git' 'pop-shell-plugin-system76-power-git')
pkgbase=pop-launcher-git
pkgver=1.2.1.r56.ga7fc5bc
pkgrel=1
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/launcher"
license=('MPL-2.0')
depends=(
'dbus'
'fd'
'libqalculate'
'pop-icon-theme-git'
'sh'
'xdg-utils'
)
makedepends=(
'cargo'
'git'
'just'
'libegl'
'libxkbcommon'
)
source=('git+https://github.com/pop-os/launcher.git')
sha256sums=('SKIP')
pkgver() {
cd launcher
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd launcher
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
just vendor
sed -i 's|{{bin-path}}|/usr/bin/pop-launcher|g' justfile
}
build() {
cd launcher
CFLAGS+=" -ffat-lto-objects"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
just build-vendored
}
check() {
cd launcher
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
just check
}
package_pop-launcher-git() {
pkgdesc="Modular IPC-based desktop launcher service"
optdepends=('pop-shell-plugin-system76-power')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
cd launcher
install -Dm755 "target/release/${pkgname%-git}-bin" "$pkgdir/usr/bin/${pkgname%-git}"
just rootdir="$pkgdir" install-plugins install-scripts
rm -rf "$pkgdir/usr/lib/${pkgname%-git}/scripts/system76-power"
}
package_pop-shell-plugin-system76-power-git() {
pkgdesc="System76 Power scripts for the launcher"
depends=('gnome-terminal' 'pop-launcher-git' 'system76-power')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}" 'pop-launcher-system76-power')
cd launcher
install -d "$pkgdir/usr/lib/${pkgbase%-git}/scripts"
cp -r scripts/system76-power "$pkgdir/usr/lib/${pkgbase%-git}/scripts"
}
|