PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Eduardo Sánchez Muñoz (eduardosm)
# Contributor: Sebastien Chassot (sinux) <seba.ptl@sinux.net>

pkgname=pothos
pkgver=0.7.1
pkgrel=1
pkgdesc="The Pothos data-flow framework"
arch=('i686' 'x86_64')
url="https://github.com/pothosware/PothosCore/wiki"
license=('boost')
depends=('python' 'poco' 'soapysdr' 'portaudio')
makedepends=('git' 'nlohmann-json')
source=(
    "git+https://github.com/pothosware/PothosCore.git#tag=pothos-$pkgver"
    "PothosFlow.desktop"
)
sha256sums=(
    'SKIP'
    '4ace40dfff405cf861845cc0f9cf772a39aabc7f3447f5fdf2d0cb74f9b166c4'
)

prepare() {
    cd "$srcdir/PothosCore"
    git submodule init
    git submodule deinit poco
    git submodule update --recursive
    # Init submodules in plotters
    git submodule update --init --recursive plotters
}

build() {
    mkdir -p "$srcdir/pothos-build"
    cd "$srcdir/pothos-build"
    cmake \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DENABLE_INTERNAL_POCO=OFF \
        -DENABLE_INTERNAL_MUPARSERX=ON \
        -DENABLE_INTERNAL_SPUCE=ON \
        "$srcdir/PothosCore"
    make
}

package() {
    cd "$srcdir/pothos-build"
    make DESTDIR="$pkgdir" install

    install -Dm644 "$srcdir/PothosFlow.desktop" "$pkgdir/usr/share/applications/PothosFlow.desktop"
    install -Dm644 "$srcdir/PothosCore/flow/icons/PothosFlow.png" "$pkgdir/usr/share/pixmaps/PothosFlow.png"
}