PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Asger Hautop Drewsen <asger@tyilo.com>

pkgname=ppm2pwg-git
pkgver=r225.32960d3
pkgrel=1
pkgdesc="Misc printing format conversion utilities: ppm2pwg, pwg2ppm, pdf2printable, baselinify, ippposter"
arch=("x86_64")
url="https://github.com/attah/ppm2pwg"
license=('GPL-3.0')
source=("git+https://github.com/attah/ppm2pwg.git")
sha512sums=('SKIP')
makedepends=('git')

prepare() {
    cd "${srcdir}/ppm2pwg"
    pwd
    git submodule update --init --recursive
}

pkgver() {
    cd "ppm2pwg"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
    cd "${srcdir}/ppm2pwg"
    make
}

package() {
    cd "${srcdir}/ppm2pwg"

    utils=(
        ppm2pwg
        pwg2ppm
        pdf2printable
        baselinify
        ippposter
    )

    for util in "${utils[@]}"; do
        install -D -m755 "$util" "${pkgdir}/usr/bin/$util"
    done
}