blob: 7a22e348fa4dccd38c2474d1254b61d6930a5f65 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Maintainer: Thomas Baechler <thomas@archlinux.org>
# Maintainer: Rustem Shaykhutdinov <buzz.rustem@gmail.com>
pkgname=ppp-eap-tls
pkgver=2.4.7
pkgrel=2
pkgdesc="EAP-TLS patched daemon which implements the Point-to-Point Protocol for dial-up networking."
arch=(i686 x86_64)
url="http://www.samba.org/ppp/"
license=('GPL' 'BSD')
depends=('glibc' 'libpcap>=1.0.0' 'openssl')
provides=('ppp')
conflicts=('ppp')
backup=(etc/ppp/{chap-secrets,pap-secrets,options,ip-up,ip-down,ip-down.d/00-dns.sh,ip-up.d/00-dns.sh,ipv6-up.d/00-iface-config.sh})
source=(https://download.samba.org/pub/ppp/ppp-${pkgver}.tar.gz{,.asc}
"https://www.nikhef.nl/~janjust/ppp/ppp-2.4.7-eaptls-mppe-1.101.patch"
ppp-2.4.6-makefiles.patch
options
ip-up
ip-down
ip-up.d.dns.sh
ip-down.d.dns.sh
ipv6-up
ipv6-down
ipv6-up.d.iface-config.sh
ppp.systemd
CVE-2015-3310.patch
ppp-build-fix.patch::"https://github.com/paulusmack/ppp/commit/50a2997b.patch"
ppp-openssl.patch::https://github.com/paulusmack/ppp/commit/3c7b86229f7bd2600d74db14b1fe5b3896be3875.patch
LICENSE)
sha256sums=('02e0a3dd3e4799e33103f70ec7df75348c8540966ee7c948e4ed8a42bbccfb30'
'SKIP'
'f7efef8dcddb3492cb1b92ee8c11a12a3330a14816627c8e6af7532a755e3992'
'f04f47318226c79594f45b8b75877c30710d22fe0fb1e2e17db3b4257dc4218c'
'0933fecb9e0adaddd88ee1e049a5f3a0508e83b81dc1aa333df784e729ab4b6e'
'ddef42b2cc5d49e81556dc9dbacf5ee3bf8dc32704f3670c2233eed42c4a4efd'
'658630ba4c5cb583df80af6d4df81df8ae20798f63cc4b9cec8d4dad13a6a897'
'aafb75b978aa13225444dc6b914fab324d686821be93c49e893800e647aa7648'
'17b486fa69a71dafcbe543dc4f2b8cb9ed31e675aabc5f6c98ef94dbc1561c85'
'bb3f44a4f2c4b8dbe7f84d77feae90a71caa9fa3c252a20c390e015d4f8ea248'
'77292b79f99f97a01aa9a75cd7cd93da70d746d3b8cc60f35b31dfe0568544c0'
'20780cf4bd0774bebb55ecb3bdae7667c9ae5cbe003a52a1ecb0bbc77d46260f'
'eb8ab2e2d71c3bb9c4297cf847b6e9d52616a3fdbf2257c479cc43dff318c831'
'f0fe7e7d9b35141c2565a09e39c4f66b475ed3fe8e2528d10faa4412f480e338'
'94225c64e806e75d6f792649c4beb26a791c4994c2701dc6a47cfccf3d91e4bf'
'3f199d83d2632274dbbe7345e5369891469f64642f28e4afb471747a88888b62'
'96fd35104e3d0ec472517afecead88419913ae73ae0189476d5dad9029c2be42')
validpgpkeys=('631E179E370CD727A7F2A33A9E4295D605F66CE9') # Paul Mackerras (Signing key) <paulus@samba.org>
prepare() {
cd "${srcdir}/ppp-${pkgver}"
patch -p1 -i "${srcdir}/ppp-2.4.6-makefiles.patch"
patch -p1 -i "${srcdir}/CVE-2015-3310.patch"
patch -p1 -i "${srcdir}/ppp-build-fix.patch"
patch -p1 -i "${srcdir}/ppp-2.4.7-eaptls-mppe-1.101.patch"
patch -p1 -i "${srcdir}/ppp-openssl.patch"
# enable active filter
sed -i "s:^#FILTER=y:FILTER=y:" pppd/Makefile.linux
# enable ipv6 support
sed -i "s:^#HAVE_INET6=y:HAVE_INET6=y:" pppd/Makefile.linux
# Enable Microsoft proprietary Callback Control Protocol
sed -i "s:^#CBCP=y:CBCP=y:" pppd/Makefile.linux
}
build() {
cd "${srcdir}/ppp-${pkgver}"
# -D_GNU_SOURCE is needed for IPv6 to work apparently
CFLAGS="$CPPFLAGS $CFLAGS -D_GNU_SOURCE" LDFLAGS="$LDFLAGS" ./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/ppp-${pkgver}"
make INSTROOT="${pkgdir}" install
install -D -m644 ../options "${pkgdir}/etc/ppp/options"
install -D -m755 ../ip-up "${pkgdir}/etc/ppp/ip-up"
install -D -m755 ../ip-down "${pkgdir}/etc/ppp/ip-down"
install -d -m755 "${pkgdir}/etc/ppp/ip-up.d"
install -d -m755 "${pkgdir}/etc/ppp/ip-down.d"
install -m755 ../ip-up.d.dns.sh "${pkgdir}/etc/ppp/ip-up.d/00-dns.sh"
install -m755 ../ip-down.d.dns.sh "${pkgdir}/etc/ppp/ip-down.d/00-dns.sh"
install -D -m755 ../ipv6-up "${pkgdir}/etc/ppp/ipv6-up"
install -D -m755 ../ipv6-down "${pkgdir}/etc/ppp/ipv6-down"
install -d -m755 "${pkgdir}/etc/ppp/ipv6-up.d"
install -d -m755 "${pkgdir}/etc/ppp/ipv6-down.d"
install -m755 ../ipv6-up.d.iface-config.sh "${pkgdir}/etc/ppp/ipv6-up.d/00-iface-config.sh"
install -D -m755 scripts/pon "${pkgdir}/usr/bin/pon"
install -D -m755 scripts/poff "${pkgdir}/usr/bin/poff"
install -D -m755 scripts/plog "${pkgdir}/usr/bin/plog"
install -D -m644 scripts/pon.1 "${pkgdir}/usr/share/man/man1/pon.1"
install -D -m600 etc.ppp/pap-secrets "${pkgdir}/etc/ppp/pap-secrets"
install -D -m600 etc.ppp/chap-secrets "${pkgdir}/etc/ppp/chap-secrets"
install -d -m755 "${pkgdir}/etc/ppp/peers"
chmod 0755 "${pkgdir}/usr/lib/pppd/${pkgver}"/*.so
install -D -m644 "${srcdir}"/ppp.systemd "${pkgdir}"/usr/lib/systemd/system/ppp@.service
install -Dm644 "$srcdir"/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|