blob: 0b21364e1a4f928a5975af7712afc86eda528efe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
pkgname=pragtical-git
_pkgname=pragtical
pkgver=3.8.2.1769365355
pkgrel=1
pkgdesc='The practical and pragmatic code editor.'
arch=('x86_64')
url="https://github.com/pragtical/pragtical"
license=('MIT')
depends=(
# Editor Dependencies
'luajit' 'sdl3' 'libiconv' 'freetype2' 'pcre2' 'uchardet' 'hicolor-icon-theme'
# Plugin Manager Dependencies
'lua' 'zlib' 'mbedtls' 'libgit2' 'libzip' 'xz'
)
makedepends=('meson>=0.58')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/pragtical/pragtical")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
echo "$(git tag -l | grep ^v | tail -n 1 | sed 's/^v//g').$(git show -s --format=%ct)"
}
build() {
cd "${_pkgname}"
local pgo
local lua="-Duse_system_lua=true"
if [ -n "$PGO" ]; then
pgo="-Db_pgo=generate"
lua="-Duse_system_lua=false"
fi
local global_data
if [ -n "$GLOBAL" ]; then
global_data="-global"
fi
arch-meson --wrap-mode default --buildtype debugoptimized $pgo -Db_lto=true \
-Dstrip=true -Doptimization=3 --force-fallback-for=sdl3_image $lua \
build
if [ -n "$PGO" ]; then
meson compile -C build
case "$XDG_SESSION_TYPE" in
wayland|x11)
./scripts/run-local $global_data build run -n scripts/lua/pgo.lua
;;
*)
SDL_VIDEO_DRIVER="dummy" \
./scripts/run-local $global_data build run -n scripts/lua/pgo.lua
;;
esac
meson configure -Db_pgo=use build
fi
meson compile -C build
}
package() {
cd "$_pkgname"
DESTDIR="$pkgdir" meson install -C build
mkdir -p "$pkgdir/usr/share/licenses/$pkgname/"
ln -s "/usr/share/doc/pragtical/licenses.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}
|