PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39


# Maintainer: Morten Linderud <morten@linderud.pw> 
# Contributor: mmm
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
# Contributor: Stefan Husmann <stefan-husmannt-online.de>

pkgname=protege
pkgver=5.2.0
pkgrel=3
pkgdesc='Free, open source ontology editor and knowledge-base framework'
arch=('any')
url='http://protege.stanford.edu/'
license=('MPL')
depends=('java-runtime>=8' 'graphviz')
makedepends=('maven' 'jdk8-openjdk')
source=("$pkgname-$pkgver.tar.gz::https://github.com/protegeproject/protege/archive/v$pkgver.tar.gz"
        "${pkgname}.sh"
        "${pkgname}.desktop"
        "${pkgname}.png")
sha256sums=('abbdd07b646b42fa29b3b2c5a169b9c7fbc9caa0aa41d3d86aa0e0724ab08e12'
            '9b0a6692d04da727ba9473399c1fdf68a85c5ec680582f79b3e46642c8cceca6'
            'e0e054d864fafdee0c7a7a034b4a92fe2fe30fcce77f2aabd71afb57dbbbb0ab'
            '3ee61d8cfcbcfc91c86c9dddc24e40f9fc0e6943bf879548340610c95d64d194')

build(){
  cd "protege-$pkgver"
  mvn clean package -Dmaven.test.skip=true
}

package() {
  cd "protege-$pkgver/protege-desktop/target/protege-$pkgver-platform-independent/Protege-$pkgver"
  install -d "${pkgdir}/usr/share/java/${pkgname}"
  cp -r * "${pkgdir}/usr/share/java/${pkgname}"
  install -d "${pkgdir}/usr/bin"
  install -D "${srcdir}/protege.sh" "${pkgdir}/usr/bin/protege"
  install -Dm644 "${srcdir}/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "${srcdir}/$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
}