summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 711179aed1bade279ac6c9b4eb21c847b5cc5e47 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Andre Schneider <andre.schneider@outlook.at>

pkgname=protonup-qt-bin
_pkgname=ProtonUp-Qt
pkgver=2.9.1
pkgrel=1
pkgdesc="Install and manage Proton-GE for Steam and Wine-GE for Lutris with this graphical user interface."
arch=('x86_64')
url="https://davidotek.github.io/protonup-qt"
license=('GPL3')
depends=('fuse2>=2.9.9')
provides=(protonup-qt)
conflicts=(protonup-qt)
options=(!strip)
source=(
  "$_pkgname-$pkgver-$CARCH.AppImage::https://github.com/DavidoTek/ProtonUp-Qt/releases/download/v$pkgver/$_pkgname-$pkgver-$CARCH.AppImage"
  "protonup-qt.desktop"
  "protonup-qt"
)
sha256sums=('ad3faf458184eb648c058842b3161cf609ef2a93a4ab3d1092bf50b4a431fd47'
            '3d2e9dbb6eb0fa034db3c1b2384fd23a8b004c90a8f72afbe86baff714433da1'
            '1baaba24e3fae798cde2f1801b9a0c5f92df5c61b0d8ba81c43731abcce44bc2')

prepare() {
  # Exctract icons from AppImage
  echo "Extracting icons from AppImage..."
  chmod 755 "$_pkgname-$pkgver-$CARCH.AppImage"
  ./"$_pkgname-$pkgver-$CARCH.AppImage" --appimage-extract > /dev/null
}

package() {
  cd "$srcdir"
  
  # Install binary and launch script
  install -Dm755 "$_pkgname-$pkgver-$CARCH.AppImage" "$pkgdir/opt/protonup-qt/protonup-qt.AppImage"
  install -Dm755 -t "$pkgdir/usr/bin" "protonup-qt"
  
  # Install icons and desktop file
  cd "squashfs-root/usr/share/icons"
  find "." -type f -exec install -Dm644 "{}" "$pkgdir/usr/share/icons/{}" \;
  cd "$srcdir"
  
  install -Dm644 -t "$pkgdir/usr/share/applications" "protonup-qt.desktop"
}