blob: e4509407eb5b50c163a3247e471fa4496d01af33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Eric Anderson <ejona86@gmail.com>
pkgname=psychonauts
pkgver=20130506
_srcpkgver=05062013
pkgrel=2
pkgdesc='A mind-bending platforming adventure (game sold separately)'
arch=('i686' 'x86_64')
url='http://www.psychonauts.com/'
license=('custom')
makedepends=('unzip')
if [ "$CARCH" = "x86_64" ]; then
depends=('lib32-sdl' 'lib32-openal' 'bash' 'lib32-gcc-libs')
else
depends=('sdl' 'openal' 'bash' 'gcc-libs')
fi
options=('!strip')
_gamepkg="${pkgname}-linux-${_srcpkgver}-bin"
source=("${pkgname}.desktop"
"psychonauts.sh"
"hib://${_gamepkg}")
md5sums=('91be805610718903bea5c3a3d1d127cf'
'095f3a6abf78d8a69538601972dfcce9'
'cd207acda0613cf06bc153b4b85dceb3')
# You can download the Humble Indie Bundle file manually, or you can configure
# DLAGENTS in makepkg.conf to auto-download.
#
# For example, to use hib-dlagent to download files set something like this in
# your makepkg.conf (change/add -k and add -u/-p to your needs):
# DLAGENTS=('hib::/usr/bin/hib-dlagent -k 1a2b3c -o %o $(echo %u | cut -c 7-)')
#
# To auto-search through a directory containing Humble Bundle downloads, you
# could set:
# DLAGENTS=('hib::/usr/bin/find /path/to/downloads -name $(echo %u | cut -c 7-) -exec ln -s \{\} %o \; -quit')
DLAGENTS+=('hib::/usr/bin/echo "Could not find %u. Download manually to \"$(pwd)\" or setup hib:// DLAGENT in /etc/makepkg.conf."; echo "Read this PKGBUILD for more info."; exit 1')
PKGEXT='.pkg.tar'
prepare(){
cd "${srcdir}"
unzip -o "${_gamepkg}" -d "${pkgname}-${pkgver}" || true
}
package(){
cd "${srcdir}/${pkgname}-${pkgver}"
mkdir -p "${pkgdir}/opt"
cp -Rl data "${pkgdir}/opt/${pkgname}"
# Use system-provided libraries
rm "${pkgdir}/opt/${pkgname}/libSDL-1.2.so.0"
rm "${pkgdir}/opt/${pkgname}/libopenal.so.1"
install -D -m644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -D -m644 data/Documents/EULAs/EULA.rtf \
"${pkgdir}/usr/share/licenses/${pkgname}/EULA.rtf"
install -D -m644 "data/Documents/EULAs/Cider-EULA-de (German).rtf" \
"${pkgdir}/usr/share/licenses/${pkgname}/Cider-EULA-de (German).rtf"
install -D -m644 "data/Documents/EULAs/Cider-EULA-en (English).rtf" \
"${pkgdir}/usr/share/licenses/${pkgname}/Cider-EULA-en (English).rtf"
install -D -m644 "data/Documents/EULAs/Cider-EULA-es (Spanish).rtf" \
"${pkgdir}/usr/share/licenses/${pkgname}/Cider-EULA-es (Spanish).rtf"
install -D -m644 "data/Documents/EULAs/Cider-EULA-fr (French).rtf" \
"${pkgdir}/usr/share/licenses/${pkgname}/Cider-EULA-fr (French).rtf"
install -D -m644 "data/Documents/EULAs/Cider-EULA-it (Italian).rtf" \
"${pkgdir}/usr/share/licenses/${pkgname}/Cider-EULA-it (Italian).rtf"
install -D -m755 "${srcdir}/psychonauts.sh" "${pkgdir}/usr/bin/${pkgname}"
}
|