blob: 091f5b6aecb4a91850c5e4c8e32525cdffbff516 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgbase=puppeteer
pkgname=($pkgbase{,-core}) #,-chromium,-firefox})
pkgver=24.37.2
pkgrel=1
pkgdesc='JavaScript API for Chrome and Firefox'
arch=(any)
url=https://pptr.dev
license=(Apache-2.0)
depends=(nodejs)
makedepends=(npm)
_archive1="$pkgbase-$pkgver"
_archive2="$pkgbase-core-$pkgver"
source=("https://registry.npmjs.org/$pkgbase/-/$_archive1.tgz"
"https://registry.npmjs.org/$pkgbase-core/-/$_archive2.tgz")
noextract=("$_archive.tgz")
sha256sums=('f42ebb71287c47900bc42963911a3faa187ee393ebb05ae6ed5f3e906e8cdbf8'
'edde3830074eda1ec088dc479accfd782a271178c3004611e77c786623715351')
_npm_i() {
npm install --no-audit --no-fund -g --prefix "$pkgdir/usr" "$1.tgz"
find "$pkgdir/usr" -type d -exec chmod 755 {} +
chown -R root:root "$pkgdir"
}
package_puppeteer() {
depends+=("$pkgname-core=$pkgver")
_npm_i "$_archive1"
rm -rf "$pkgdir/usr/lib/node_modules/$pkgname/node_modules/$pkgname-core"
}
package_puppeteer-core() {
optdepends=('chromium: for use with Chrome'
'firefox: for use with Firefox')
_npm_i "$_archive2"
}
package_puppeteer-chromium() {
depends+=("$pkgbase=$pkgver" chromium)
}
package_puppeteer-firefox() {
depends+=("$pkgbase=$pkgver" firefox)
}
|