blob: 92a757195d5bedd4b02ab51db58b2b838491686f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Adam Perkowski <adas1per@protonmail.com>
# https://github.com/adamperkowski/PKGBUILDs
pkgname=purr
pkgver=1.2.0
pkgrel=1
pkgdesc='Unoffical CLI for Catppuccin port developers'
arch=('x86_64')
url="https://github.com/uncenter/$pkgname"
license=('MIT')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('72abf6c2b647610edcbe4bea31f6359fdac8c6a19077f13c314bda0ab6a09a46')
makedepends=('cargo')
depends=('glibc' 'gcc-libs' 'openssl')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm644 CHANGELOG.md -t "$pkgdir/usr/share/doc/$pkgname"
}
# vim: ts=2 sw=2 et:
|