blob: a4f55ab2d542def1d8b001a55981e4b22778d9b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=pypipe-git
_gitpkgname=pypipe
pkgver=r83.29f6595
pkgrel=1
pkgdesc='Python command-line tool for pipeline processing'
arch=('any')
url='https://github.com/bugen/pypipe'
license=('Apache-2.0')
depends=('bash' 'python')
makedepends=(
'git'
'python-build'
'python-hatchling'
'python-installer'
'python-wheel'
)
checkdepends=('python-pytest')
provides=('pypipe')
conflicts=('pypipe')
options=('!debug' '!strip')
source=(
"${_gitpkgname}::git+https://github.com/bugen/pypipe.git"
)
sha512sums=(
'SKIP'
)
pkgver() {
printf "r%s.%s" \
"$(git -C "${_gitpkgname}" rev-list --count HEAD)" \
"$(git -C "${_gitpkgname}" rev-parse --short HEAD)"
}
prepare() {
git -C "${srcdir}/${_gitpkgname}" clean -dfx
}
build() {
cd "${srcdir}/${_gitpkgname}"
python -m build --wheel --no-isolation
}
check() {
cd "${srcdir}/${_gitpkgname}"
python -m pytest -v tests/
}
package() {
cd "${srcdir}/${_gitpkgname}"
echo >&2 'Packaging script'
python -I -m installer --destdir="${pkgdir}" dist/*.whl
echo >&2 'Packaging examples'
install -D -m 644 -t "${pkgdir}/usr/share/${pkgname}/examples" docs/*
echo >&2 'Packaging the documentation'
install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" 'README.md'
echo >&2 'Packaging the license'
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" 'LICENSE'
}
|